pkgs/by-name/ei/eiwd/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , autoreconfHook
   5 , pkg-config
   6 , python3Packages  # for tests
   7 , openssl          # for tests
   8 , enableManpages ? true
   9 , docutils         # for manpages
  10 }:
  11
  12 stdenv.mkDerivation (finalAttrs: {
  13   pname = "eiwd";
  14   version = "2.16-1";
  15
  16   src = fetchFromGitHub {
  17     owner = "illiliti";
  18     repo = "eiwd";
  19     rev = finalAttrs.version;
  20     hash = "sha256-TQA9aVdXGX2hje7lRQ8T9QDpSTYGpB5cIDlNYsUg/dM=";
  21     fetchSubmodules = true;
  22   };
  23
  24   outputs = [
  25     "out" "doc"
  26   ] ++ lib.optionals enableManpages [
  27     "man"
  28   ] ++ lib.optionals finalAttrs.doCheck [
  29     "test"
  30   ];
  31
  32   postUnpack = ''
  33     patchShebangs .
  34   '';
  35
  36   nativeBuildInputs = [
  37     autoreconfHook
  38     pkg-config
  39   ] ++ lib.optionals enableManpages [
  40     docutils    # only for the man pages
  41   ];
  42
  43   checkInputs = [
  44     python3Packages.python
  45     (lib.getBin openssl)
  46   ];
  47
  48   configureFlags = [
  49     "--disable-dbus"
  50   ] ++ lib.optionals (!enableManpages) [
  51     "--disable-manual-pages"
  52   ];
  53
  54   enableParallelBuilding = true;
  55
  56   # override this to false if you don't want to build python3
  57   doCheck = stdenv.hostPlatform == stdenv.buildPlatform;
  58
  59   # prevent the `install-data-local` Makefile rule from running;
  60   # all it does is attempt to `mkdir` the `localstatedir`.
  61   preInstall = ''
  62     mkdir install-data-local
  63     substituteInPlace Makefile --replace \
  64       '$(MKDIR_P) -m 700 $(DESTDIR)$(daemon_storagedir)' \
  65       'true'
  66   '';
  67
  68   postInstall = ''
  69     mkdir -p $doc/share/doc
  70     cp -a doc $doc/share/doc/iwd
  71     cp -a README AUTHORS TODO $doc/share/doc/iwd
  72   '' + lib.optionalString finalAttrs.finalPackage.doCheck ''
  73     mkdir -p $test/bin
  74     cp -a test/* $test/bin/
  75   '';
  76
  77   meta = with lib; {
  78     homepage = "https://github.com/illiliti/eiwd/";
  79     description = "Fork of iwd (wifi daemon) which does not require dbus";
  80     license = licenses.lgpl21Plus;
  81     platforms = platforms.linux;
  82   };
  83 })