pkgs/by-name/em/emulationstation/package.nix

   1 {
   2   lib,
   3   SDL2,
   4   alsa-lib,
   5   boost,
   6   callPackage,
   7   cmake,
   8   curl,
   9   freeimage,
  10   freetype,
  11   libGL,
  12   libGLU,
  13   libvlc,
  14   pkg-config,
  15   rapidjson,
  16   stdenv,
  17 }:
  18
  19 let
  20   sources = callPackage ./sources.nix { };
  21 in
  22 stdenv.mkDerivation {
  23   inherit (sources.emulationstation) pname version src;
  24
  25   postUnpack = ''
  26     pushd $sourceRoot/external/pugixml
  27     cp --verbose --archive ${sources.pugixml.src}/* .
  28     chmod --recursive 744 .
  29     popd
  30   '';
  31
  32   nativeBuildInputs = [
  33     SDL2
  34     cmake
  35     pkg-config
  36   ];
  37
  38   buildInputs = [
  39     SDL2
  40     alsa-lib
  41     boost
  42     curl
  43     freeimage
  44     freetype
  45     libGL
  46     libGLU
  47     libvlc
  48     rapidjson
  49   ];
  50
  51   cmakeFlags = [ (lib.cmakeBool "GL" true) ];
  52
  53   strictDeps = true;
  54
  55   installPhase = ''
  56     runHook preInstall
  57
  58     install -Dm755 ../emulationstation $out/bin/emulationstation
  59     mkdir -p $out/share/emulationstation/
  60     cp -r ../resources $out/share/emulationstation/
  61
  62     runHook postInstall
  63   '';
  64
  65   # es-core/src/resources/ResourceManager.cpp: resources are searched at the
  66   # same place of binaries.
  67   postFixup = ''
  68     pushd $out
  69     ln -s $out/share/emulationstation/resources $out/bin/
  70     popd
  71   '';
  72
  73   passthru = {
  74     inherit sources;
  75   };
  76
  77   meta = {
  78     homepage = "https://github.com/RetroPie/EmulationStation";
  79     description = "Flexible emulator front-end supporting keyboardless navigation and custom system themes (forked by RetroPie)";
  80     license = with lib.licenses; [ mit ];
  81     mainProgram = "emulationstation";
  82     maintainers = with lib.maintainers; [
  83       AndersonTorres
  84       edwtjo
  85     ];
  86     platforms = lib.platforms.linux;
  87   };
  88 }