pkgs/by-name/eu/eudev/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , autoreconfHook
   5 , gperf
   6 , kmod
   7 , pkg-config
   8 , util-linux
   9 }:
  10
  11 stdenv.mkDerivation (finalAttrs: {
  12   pname = "eudev";
  13   version = "3.2.14";
  14
  15   src = fetchFromGitHub {
  16     owner = "eudev-project";
  17     repo = "eudev";
  18     rev = "v${finalAttrs.version}";
  19     hash = "sha256-v/szzqrBedQPRGYkZ0lV9rslCH//uqGp4PHEF0/51Lg=";
  20   };
  21
  22   nativeBuildInputs = [
  23     autoreconfHook
  24     gperf
  25     pkg-config
  26   ];
  27
  28   buildInputs = [
  29     kmod
  30     util-linux
  31   ];
  32
  33   configureFlags = [
  34     "--localstatedir=/var"
  35     "--sysconfdir=/etc"
  36   ];
  37
  38   makeFlags = [
  39     "hwdb_bin=/var/lib/udev/hwdb.bin"
  40     "udevrulesdir=/etc/udev/rules.d"
  41   ];
  42
  43   preInstall = ''
  44     # Disable install-exec-hook target, as it conflicts with our move-sbin
  45     # setup-hook
  46
  47     sed -i 's;$(MAKE) $(AM_MAKEFLAGS) install-exec-hook;$(MAKE) $(AM_MAKEFLAGS);g' src/udev/Makefile
  48   '';
  49
  50   installFlags = [
  51     "localstatedir=$(TMPDIR)/var"
  52     "sysconfdir=$(out)/etc"
  53     "udevconfdir=$(out)/etc/udev"
  54     "udevhwdbbin=$(out)/var/lib/udev/hwdb.bin"
  55     "udevhwdbdir=$(out)/var/lib/udev/hwdb.d"
  56     "udevrulesdir=$(out)/var/lib/udev/rules.d"
  57   ];
  58
  59   meta = {
  60     homepage = "https://github.com/eudev-project/eudev";
  61     description = "Fork of udev with the aim of isolating it from init";
  62     longDescription = ''
  63       eudev is a standalone dynamic and persistent device naming support (aka
  64       userspace devfs) daemon that runs independently from the init
  65       system. eudev strives to remain init system and linux distribution
  66       neutral. It is currently used as the devfs manager for more than a dozen
  67       different linux distributions.
  68
  69       This git repo is a fork of systemd repository with the aim of isolating
  70       udev from any particular flavor of system initialization. In this case,
  71       the isolation is from systemd.
  72
  73       This is a project started by Gentoo developers and testing was initially
  74       being done mostly on OpenRC. We welcome contribution from others using a
  75       variety of system initializations to ensure eudev remains system
  76       initialization and distribution neutral. On 2021-08-20 Gentoo decided to
  77       abandon eudev and a new project was established on 2021-09-14 by Alpine,
  78       Devuan and Gentoo contributors.
  79     '';
  80     changelog = "https://github.com/eudev-project/eudev/releases/tag/${finalAttrs.src.rev}";
  81     license = lib.licenses.gpl2Plus;
  82     maintainers = with lib.maintainers; [ raskin AndersonTorres ];
  83     inherit (kmod.meta) platforms;
  84   };
  85 })