pkgs/by-name/fo/fortune-kind/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , rustPlatform
   5 , darwin
   6 , libiconv
   7 , makeBinaryWrapper
   8 , installShellFiles
   9 , fortuneAlias ? true
  10 }:
  11
  12 rustPlatform.buildRustPackage rec {
  13   pname = "fortune-kind";
  14   version = "0.1.13";
  15
  16   src = fetchFromGitHub {
  17     owner = "cafkafk";
  18     repo = "fortune-kind";
  19     rev = "v${version}";
  20     hash = "sha256-Tpg0Jq2EhkwQuz5ZOtv6Rb5YESSlmzLoJPTxYJNNgac=";
  21   };
  22
  23   cargoHash = "sha256-hxbvsAQsZWUAgj8QAlcxqBA5YagLO3/vz9lQGJMHUjw=";
  24
  25   nativeBuildInputs = [ makeBinaryWrapper installShellFiles ];
  26   buildInputs = lib.optionals stdenv.hostPlatform.isDarwin [ libiconv darwin.apple_sdk.frameworks.Security ];
  27
  28   buildNoDefaultFeatures = true;
  29
  30   MAN_OUT = "./man";
  31
  32   preBuild = ''
  33     mkdir -p "./$MAN_OUT";
  34   '';
  35
  36   preInstall = ''
  37     installManPage man/fortune-kind.1
  38     installShellCompletion \
  39       --fish man/fortune-kind.fish \
  40       --bash man/fortune-kind.bash \
  41       --zsh  man/_fortune-kind
  42     mkdir -p $out
  43     cp -r $src/fortunes $out/fortunes;
  44   '';
  45
  46   postInstall = ''
  47     wrapProgram $out/bin/fortune-kind \
  48       --prefix FORTUNE_DIR : "$out/fortunes"
  49   ''+ lib.optionalString fortuneAlias ''
  50     ln -s fortune-kind $out/bin/fortune
  51   '';
  52
  53   meta = with lib; {
  54     description = "Kinder, curated fortune, written in rust";
  55     longDescription = ''
  56       Historically, contributions to fortune-mod have had a less-than ideal
  57       quality control process, and as such, many of the fortunes that a user may
  58       receive from the program read more like cryptic inside jokes, or at the
  59       very worst, locker-room banter. One of the major goals of fortune-kind is
  60       defining and applying a somewhat more rigorous moderation and editing
  61       process to the fortune adoption workflow.
  62     '';
  63     homepage = "https://github.com/cafkafk/fortune-kind";
  64     changelog = "https://github.com/cafkafk/fortune-kind/releases/tag/v${version}";
  65     license = licenses.gpl3Only;
  66     mainProgram = "fortune-kind";
  67     maintainers = with maintainers; [ cafkafk ];
  68     platforms = platforms.unix ++ platforms.windows;
  69   };
  70 }