pkgs/by-name/ge/gepetto-viewer-corba/package.nix

   1 {
   2   boost,
   3   cmake,
   4   doxygen,
   5   fetchFromGitHub,
   6   fontconfig,
   7   gepetto-viewer,
   8   lib,
   9   pkg-config,
  10   python3Packages,
  11   libsForQt5,
  12   stdenv,
  13 }:
  14
  15 stdenv.mkDerivation (finalAttrs: {
  16   pname = "gepetto-viewer-corba";
  17   version = "5.8.0";
  18   pyproject = false; # CMake
  19
  20   src = fetchFromGitHub {
  21     owner = "gepetto";
  22     repo = "gepetto-viewer-corba";
  23     rev = "v${finalAttrs.version}";
  24     hash = "sha256-/bpAs4ca/+QjWEGuHhuDT8Ts2Ggg+DZWETZfjho6E0w=";
  25   };
  26
  27   outputs = [
  28     "out"
  29     "doc"
  30   ];
  31
  32   postPatch = ''
  33     substituteInPlace src/CMakeLists.txt \
  34       --replace-fail "ARGUMENTS $" "ARGUMENTS -p${python3Packages.omniorbpy}/${python3Packages.python.sitePackages} $" \
  35       --replace-fail '$'{CMAKE_SOURCE_DIR}/cmake '$'{JRL_CMAKE_MODULES}
  36   '';
  37
  38   buildInputs = [ libsForQt5.qtbase ];
  39
  40   nativeBuildInputs = [
  41     cmake
  42     doxygen
  43     libsForQt5.wrapQtAppsHook
  44     pkg-config
  45     python3Packages.omniorb
  46   ];
  47
  48   propagatedBuildInputs = [
  49     python3Packages.boost
  50     python3Packages.gepetto-viewer
  51     python3Packages.omniorbpy
  52   ];
  53
  54   doCheck = true;
  55
  56   # Fontconfig error: Cannot load default config file: No such file: (null)
  57   env.FONTCONFIG_FILE = "${fontconfig.out}/etc/fonts/fonts.conf";
  58
  59   # Fontconfig error: No writable cache directories
  60   preBuild = "export XDG_CACHE_HOME=$(mktemp -d)";
  61
  62   meta = {
  63     homepage = "https://github.com/gepetto/gepetto-viewer-corba";
  64     description = "CORBA client/server for gepetto-viewer.";
  65     license = lib.licenses.bsd3;
  66     maintainers = [ lib.maintainers.nim65s ];
  67     platforms = lib.platforms.unix;
  68   };
  69 })