pkgs/by-name/gp/gprename/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchzip,
   5   makeWrapper,
   6   moreutils,
   7   perlPackages,
   8   gtk3,
   9   pango,
  10   harfbuzz,
  11   gdk-pixbuf,
  12   at-spi2-atk,
  13 }:
  14 stdenv.mkDerivation (finalAttrs: {
  15   pname = "gprename";
  16   version = "20230429";
  17
  18   src = fetchzip {
  19     url = "mirror://sourceforge/gprename/gprename-${finalAttrs.version}.zip";
  20     hash = "sha256-Du9OO2qeB1jUEJFcVYmLbJAGi2p/IVe3sqladq09AyY=";
  21   };
  22
  23   nativeBuildInputs = [
  24     makeWrapper
  25     moreutils
  26   ];
  27
  28   postPatch = ''
  29     grep -Ev 'desktop-file-install|update-desktop-database' Makefile | sponge Makefile
  30
  31     substituteInPlace Makefile \
  32       --replace '/usr/share' '$(DESTDIR)/share'
  33
  34     substituteInPlace bin/gprename \
  35       --replace '/usr/share' $out/share \
  36       --replace '/usr/local/share' $out/share
  37   '';
  38
  39   makeFlags = [ "DESTDIR=$(out)" ];
  40   buildInputs = [
  41     perlPackages.perl
  42     pango
  43   ];
  44   postInstall = ''
  45     wrapProgram $out/bin/gprename \
  46       --set PERL5LIB ${
  47         perlPackages.makeFullPerlPath (
  48           with perlPackages; [
  49             Pango
  50             Glib
  51             Gtk3
  52             LocaleGettext
  53             libintl-perl
  54           ]
  55         )
  56       } \
  57       --prefix GI_TYPELIB_PATH : ${
  58         lib.makeSearchPath "/lib/girepository-1.0" [
  59           gtk3
  60           pango.out
  61           harfbuzz
  62           gdk-pixbuf
  63           at-spi2-atk
  64         ]
  65       }
  66   '';
  67
  68   meta = {
  69     description = "Complete batch renamer for files and directories";
  70     homepage = "https://gprename.sourceforge.net/index.php";
  71     license = lib.licenses.gpl3Plus;
  72     mainProgram = "gprename";
  73     maintainers = with lib.maintainers; [ quantenzitrone ];
  74   };
  75 })