pkgs/by-name/gp/gpu-viewer/package.nix

   1 {
   2   lib,
   3   python3Packages,
   4   fetchFromGitHub,
   5
   6   # nativeBuildInputs
   7   gobject-introspection,
   8   meson,
   9   ninja,
  10   pkg-config,
  11   wrapGAppsHook4,
  12
  13   # buildInputs
  14   gdk-pixbuf,
  15   gtk4,
  16   libadwaita,
  17   vulkan-tools,
  18
  19   # wrapper
  20   python3,
  21   clinfo,
  22   lsb-release,
  23   mesa-demos,
  24   vdpauinfo,
  25 }:
  26
  27 python3Packages.buildPythonApplication rec {
  28   pname = "gpu-viewer";
  29   version = "3.06";
  30
  31   format = "other";
  32
  33   src = fetchFromGitHub {
  34     owner = "arunsivaramanneo";
  35     repo = "gpu-viewer";
  36     rev = "refs/tags/v${version}";
  37     hash = "sha256-vFU2VdafY1HmPGRa20PwT6n+Xf4bKBzKJ5jWpvwyMWg=";
  38   };
  39
  40   nativeBuildInputs = [
  41     gobject-introspection
  42     meson
  43     ninja
  44     pkg-config
  45     wrapGAppsHook4
  46   ];
  47
  48   buildInputs = [
  49     gdk-pixbuf
  50     gtk4
  51     libadwaita
  52     vulkan-tools
  53   ];
  54
  55   pythonPath = with python3Packages; [
  56     click
  57     pygobject3
  58   ];
  59
  60   # Prevent double wrapping
  61   dontWrapGApps = true;
  62
  63   postFixup = ''
  64     makeWrapper ${python3.interpreter} $out/bin/gpu-viewer \
  65       --prefix PATH : "${
  66         lib.makeBinPath [
  67           clinfo
  68           lsb-release
  69           mesa-demos
  70           vdpauinfo
  71           vulkan-tools
  72         ]
  73       }" \
  74       --add-flags "$out/share/gpu-viewer/Files/GPUViewer.py" \
  75       --prefix PYTHONPATH : "$PYTHONPATH" \
  76       --chdir "$out/share/gpu-viewer/Files" \
  77       ''${makeWrapperArgs[@]} \
  78       ''${gappsWrapperArgs[@]}
  79   '';
  80
  81   meta = {
  82     homepage = "https://github.com/arunsivaramanneo/GPU-Viewer";
  83     description = "Front-end to glxinfo, vulkaninfo, clinfo and es2_info";
  84     changelog = "https://github.com/arunsivaramanneo/GPU-Viewer/releases/tag/v${version}";
  85     maintainers = with lib.maintainers; [ GaetanLepage ];
  86     license = lib.licenses.gpl3;
  87     platforms = lib.platforms.linux;
  88     mainProgram = "gpu-viewer";
  89   };
  90 }