pkgs/by-name/ll/lldap-cli/package.nix

   1 { stdenv
   2 , lib
   3 , fetchFromGitHub
   4 , bash
   5 , coreutils
   6 , gnugrep
   7 , gnused
   8 , jq
   9 , curl
  10 , makeWrapper
  11 }:
  12 stdenv.mkDerivation {
  13   pname = "lldap-cli";
  14   version = "0-unstable-2024-02-24";
  15
  16   src = fetchFromGitHub {
  17     owner = "Zepmann";
  18     repo = "lldap-cli";
  19     rev = "d1fe50006c4a3a1796d4fb2d73d8c8dcfc875fd5";
  20     hash = "sha256-ZKRTYdgtOfV7TgpaVKLhYrCttYvB/bUexMshmmF8NyY=";
  21   };
  22
  23   nativeBuildInputs = [ makeWrapper ];
  24
  25   patchPhase = ''
  26     runHook prePatch
  27
  28     # fix .lldap-cli-wrapped showing up in usage
  29     substituteInPlace lldap-cli \
  30       --replace-fail '$(basename $0)' lldap-cli
  31
  32     runHook postPatch
  33   '';
  34
  35   dontConfigure = true;
  36   dontBuild = true;
  37
  38   installPhase = ''
  39     install -Dm555 lldap-cli -t $out/bin
  40     wrapProgram $out/bin/lldap-cli \
  41       --prefix PATH : ${lib.makeBinPath [ bash coreutils gnugrep gnused jq curl ]}
  42   '';
  43
  44   meta = {
  45     description = "Command line tool for managing LLDAP";
  46     longDescription = ''
  47       LDAP-CLI is a command line interface for LLDAP.
  48
  49       LLDAP uses GraphQL to offer an HTTP-based API.
  50       This API is used by an included web-based user interface.
  51       Unfortunately, LLDAP lacks a command-line interface,
  52       which is a necessity for any serious administrator.
  53       LLDAP-CLI translates CLI commands to GraphQL API calls.
  54     '';
  55     homepage = "https://github.com/Zepmann/lldap-cli";
  56     license = lib.licenses.gpl3Only;
  57     maintainers = [ lib.maintainers.nw ];
  58     mainProgram = "lldap-cli";
  59     platforms = lib.platforms.unix;
  60   };
  61 }