pkgs/by-name/me/merkaartor/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   cmake,
   6   pkg-config,
   7   gdal,
   8   proj,
   9   protobuf,
  10   qt5,
  11   withGeoimage ? true,
  12   exiv2,
  13   withGpsdlib ? (!stdenv.hostPlatform.isDarwin),
  14   gpsd,
  15   withLibproxy ? false,
  16   libproxy,
  17   withZbar ? false,
  18   zbar,
  19 }:
  20
  21 stdenv.mkDerivation rec {
  22   pname = "merkaartor";
  23   version = "0.20.0";
  24
  25   src = fetchFromGitHub {
  26     owner = "openstreetmap";
  27     repo = "merkaartor";
  28     rev = version;
  29     hash = "sha256-oxLGhIE1qJ9+GOztD1HvrLGRGVO3gyy7Rc6CyzKTFec=";
  30   };
  31
  32   nativeBuildInputs = [
  33     cmake
  34     pkg-config
  35     qt5.qttools
  36     qt5.wrapQtAppsHook
  37   ];
  38
  39   buildInputs =
  40     [
  41       gdal
  42       proj
  43       protobuf
  44       qt5.qtnetworkauth
  45       qt5.qtsvg
  46       qt5.qtwebengine
  47     ]
  48     ++ lib.optional withGeoimage exiv2
  49     ++ lib.optional withGpsdlib gpsd
  50     ++ lib.optional withLibproxy libproxy
  51     ++ lib.optional withZbar zbar;
  52
  53   cmakeFlags = [
  54     (lib.cmakeBool "GEOIMAGE" withGeoimage)
  55     (lib.cmakeBool "GPSD" withGpsdlib)
  56     (lib.cmakeBool "LIBPROXY" withLibproxy)
  57     (lib.cmakeBool "WEBENGINE" true)
  58     (lib.cmakeBool "ZBAR" withZbar)
  59   ];
  60
  61   postInstall = lib.optionalString stdenv.hostPlatform.isDarwin ''
  62     mkdir -p $out/{Applications,bin}
  63     mv $out/merkaartor.app $out/Applications
  64     # Prevent wrapping, otherwise plugins will not be loaded
  65     chmod -x $out/Applications/merkaartor.app/Contents/plugins/background/*.dylib
  66     makeWrapper $out/{Applications/merkaartor.app/Contents/MacOS,bin}/merkaartor
  67   '';
  68
  69   meta = {
  70     description = "OpenStreetMap editor";
  71     homepage = "http://merkaartor.be/";
  72     license = lib.licenses.gpl2Plus;
  73     mainProgram = "merkaartor";
  74     maintainers = with lib.maintainers; [ sikmir ];
  75     platforms = lib.platforms.unix;
  76   };
  77 }