pkgs/by-name/ml/mlx42/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   cmake,
   6   glfw,
   7   darwin,
   8   enableShared ? !stdenv.hostPlatform.isStatic,
   9   enableDebug ? false,
  10 }:
  11
  12 stdenv.mkDerivation (finalAttrs: {
  13   pname = "mlx42";
  14   version = "2.3.4";
  15
  16   src = fetchFromGitHub {
  17     owner = "codam-coding-college";
  18     repo = "MLX42";
  19     rev = "refs/tags/v${finalAttrs.version}";
  20     hash = "sha256-c4LoTePHhQeZTx33V1K3ZyXmT7vjB6NdkGVAiSuJKfI=";
  21   };
  22
  23   postPatch =
  24     ''
  25       patchShebangs --build ./tools
  26     ''
  27     + lib.optionalString enableShared ''
  28       substituteInPlace CMakeLists.txt \
  29           --replace-fail "mlx42 STATIC" "mlx42 SHARED"
  30     '';
  31
  32   strictDeps = true;
  33
  34   nativeBuildInputs = [ cmake ];
  35
  36   buildInputs =
  37     [ glfw ]
  38     ++ lib.optionals stdenv.hostPlatform.isDarwin (
  39       with darwin.apple_sdk.frameworks;
  40       [
  41         OpenGL
  42         Cocoa
  43         IOKit
  44       ]
  45     );
  46
  47   cmakeFlags = [ (lib.cmakeBool "DEBUG" enableDebug) ];
  48
  49   postInstall = ''
  50     mkdir -p $out/lib/pkgconfig
  51     substituteAll ${./mlx42.pc} $out/lib/pkgconfig/mlx42.pc
  52   '';
  53
  54   meta = {
  55     changelog = "https://github.com/codam-coding-college/MLX42/releases/tag/v${finalAttrs.version}";
  56     description = "Simple cross-platform graphics library that uses GLFW and OpenGL";
  57     homepage = "https://github.com/codam-coding-college/MLX42";
  58     license = lib.licenses.gpl2Only;
  59     maintainers = with lib.maintainers; [ tomasajt ];
  60     platforms = lib.platforms.unix;
  61   };
  62 })