pkgs/by-name/ne/nemo-python/package.nix

   1 { stdenv
   2 , lib
   3 , fetchFromGitHub
   4 , meson
   5 , pkg-config
   6 , ninja
   7 , glib
   8 , gtk3
   9 , nemo
  10 , python3
  11 }:
  12
  13 stdenv.mkDerivation rec {
  14   pname = "nemo-python";
  15   version = "6.2.0";
  16
  17   src = fetchFromGitHub {
  18     owner = "linuxmint";
  19     repo = "nemo-extensions";
  20     rev = version;
  21     hash = "sha256-qghGgd+OWYiXvcGUfgiQT6rR4mJPAOfOtYB3lWLg4iA=";
  22   };
  23
  24   sourceRoot = "${src.name}/nemo-python";
  25
  26   patches = [
  27     # Load extensions from NEMO_PYTHON_EXTENSION_DIR environment variable
  28     # https://github.com/NixOS/nixpkgs/issues/78327
  29     ./load-extensions-from-env.patch
  30
  31     # Pick up all passthru.nemoPythonExtensionDeps via nemo-with-extensions wrapper
  32     ./python-path.patch
  33   ];
  34
  35   nativeBuildInputs = [
  36     meson
  37     pkg-config
  38     ninja
  39   ];
  40
  41   buildInputs = [
  42     glib
  43     gtk3
  44     nemo
  45     python3
  46     python3.pkgs.pygobject3
  47   ];
  48
  49   postPatch = ''
  50     # Tries to load libpython3.so via g_module_open ().
  51     substituteInPlace meson.build \
  52       --replace "get_option('prefix'), get_option('libdir')" "'${python3}/lib'"
  53   '';
  54
  55   PKG_CONFIG_LIBNEMO_EXTENSION_EXTENSIONDIR = "${placeholder "out"}/${nemo.extensiondir}";
  56
  57   passthru.nemoPythonExtensionDeps = [ python3.pkgs.pygobject3 ];
  58
  59   meta = with lib; {
  60     homepage = "https://github.com/linuxmint/nemo-extensions/tree/master/nemo-python";
  61     description = "Python bindings for the Nemo extension library";
  62     license = licenses.gpl2Plus;
  63     platforms = platforms.linux;
  64     maintainers = teams.cinnamon.members;
  65   };
  66 }