pkgs/by-name/no/noto-fonts-color-emoji/package.nix

   1 { lib
   2 , stdenvNoCC
   3 , fetchFromGitHub
   4 , buildPackages
   5 , pkg-config
   6 , cairo
   7 , imagemagick
   8 , zopfli
   9 , pngquant
  10 , which
  11 }:
  12
  13 let
  14   emojiPythonEnv =
  15     buildPackages.python3.withPackages (p: with p; [ fonttools nototools ]);
  16 in
  17 stdenvNoCC.mkDerivation rec {
  18   pname = "noto-fonts-color-emoji";
  19   version = "2.042";
  20
  21   src = fetchFromGitHub {
  22     owner = "googlefonts";
  23     repo = "noto-emoji";
  24     rev = "v${version}";
  25     hash = "sha256-otJQMXrBIPrxD1vCdgcrZ2h1a9XAMbqEBFumjz1XJ54=";
  26   };
  27
  28   depsBuildBuild = [
  29     buildPackages.stdenv.cc
  30     pkg-config
  31     cairo
  32   ];
  33
  34   nativeBuildInputs = [
  35     imagemagick
  36     zopfli
  37     pngquant
  38     which
  39     emojiPythonEnv
  40   ];
  41
  42   postPatch = ''
  43     patchShebangs *.py
  44     patchShebangs third_party/color_emoji/*.py
  45     # remove check for virtualenv, since we handle
  46     # python requirements using python.withPackages
  47     sed -i '/ifndef VIRTUAL_ENV/,+2d' Makefile
  48     # Make the build verbose so it won't get culled by Hydra thinking that
  49     # it somehow got stuck doing nothing.
  50     sed -i 's;\t@;\t;' Makefile
  51   '';
  52
  53   buildFlags = [ "BYPASS_SEQUENCE_CHECK=True" ];
  54
  55   enableParallelBuilding = true;
  56
  57   installPhase = ''
  58     runHook preInstall
  59     mkdir -p $out/share/fonts/noto
  60     cp NotoColorEmoji.ttf $out/share/fonts/noto
  61     runHook postInstall
  62   '';
  63
  64   meta = {
  65     description = "Color emoji font";
  66     homepage = "https://github.com/googlefonts/noto-emoji";
  67     license = with lib.licenses; [ ofl asl20 ];
  68     platforms = lib.platforms.all;
  69     maintainers = with lib.maintainers; [ mathnerd314 sternenseemann ];
  70   };
  71 }