pkgs/by-name/or/orca/package.nix

   1 { lib
   2 , pkg-config
   3 , fetchurl
   4 , meson
   5 , ninja
   6 , wrapGAppsHook3
   7 , gobject-introspection
   8 , gettext
   9 , yelp-tools
  10 , itstool
  11 , python3
  12 , gtk3
  13 , gnome
  14 , substituteAll
  15 , at-spi2-atk
  16 , at-spi2-core
  17 , dbus
  18 , xkbcomp
  19 , procps
  20 , lsof
  21 , coreutils
  22 , gsettings-desktop-schemas
  23 , speechd-minimal
  24 , brltty
  25 , liblouis
  26 , gst_all_1
  27 }:
  28
  29 python3.pkgs.buildPythonApplication rec {
  30   pname = "orca";
  31   version = "46.2";
  32
  33   format = "other";
  34
  35   src = fetchurl {
  36     url = "mirror://gnome/sources/${pname}/${lib.versions.major version}/${pname}-${version}.tar.xz";
  37     hash = "sha256-j2MpmxpPnDCFfCKfapzhbyxD6u6pD7+QkxTKi7c+/V4=";
  38   };
  39
  40   patches = [
  41     (substituteAll {
  42       src = ./fix-paths.patch;
  43       cat = "${coreutils}/bin/cat";
  44       lsof = "${lsof}/bin/lsof";
  45       pgrep = "${procps}/bin/pgrep";
  46       xkbcomp = "${xkbcomp}/bin/xkbcomp";
  47     })
  48   ];
  49
  50   nativeBuildInputs = [
  51     meson
  52     ninja
  53     wrapGAppsHook3
  54     pkg-config
  55     gettext
  56     yelp-tools
  57     itstool
  58     gobject-introspection
  59   ];
  60
  61   pythonPath = with python3.pkgs; [
  62     pygobject3
  63     dbus-python
  64     pyxdg
  65     brltty
  66     liblouis
  67     psutil
  68     speechd-minimal
  69     gst-python
  70     setproctitle
  71   ];
  72
  73   strictDeps = false;
  74
  75   buildInputs = [
  76     python3
  77     gtk3
  78     at-spi2-atk
  79     at-spi2-core
  80     dbus
  81     gsettings-desktop-schemas
  82     gst_all_1.gstreamer
  83     gst_all_1.gst-plugins-base
  84     gst_all_1.gst-plugins-good
  85   ];
  86
  87   dontWrapGApps = true; # Prevent double wrapping
  88
  89   preFixup = ''
  90     makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
  91   '';
  92
  93   passthru = {
  94     updateScript = gnome.updateScript {
  95       packageName = pname;
  96     };
  97   };
  98
  99   meta = with lib; {
 100     homepage = "https://orca.gnome.org/";
 101     changelog = "https://gitlab.gnome.org/GNOME/orca/-/blob/main/NEWS";
 102     description = "Screen reader";
 103     mainProgram = "orca";
 104     longDescription = ''
 105       A free, open source, flexible and extensible screen reader that provides
 106       access to the graphical desktop via speech and refreshable braille.
 107       It works with applications and toolkits that support the Assistive
 108       Technology Service Provider Interface (AT-SPI). That includes the GNOME
 109       GTK toolkit, the Java platform's Swing toolkit, LibreOffice, Gecko, and
 110       WebKitGtk. AT-SPI support for the KDE Qt toolkit is being pursued.
 111
 112       Needs `services.gnome.at-spi2-core.enable = true;` in `configuration.nix`.
 113     '';
 114     maintainers = with maintainers; [ berce ] ++ teams.gnome.members;
 115     license = licenses.lgpl21;
 116     platforms = platforms.linux;
 117   };
 118 }