pkgs/by-name/pr/proxsuite/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   fetchpatch,
   6   cereal_1_3_2,
   7   cmake,
   8   doxygen,
   9   eigen,
  10   fontconfig,
  11   graphviz,
  12   jrl-cmakemodules,
  13   simde,
  14   matio,
  15   pythonSupport ? false,
  16   python3Packages,
  17 }:
  18 stdenv.mkDerivation (finalAttrs: {
  19   pname = "proxsuite";
  20   version = "0.6.7";
  21
  22   src = fetchFromGitHub {
  23     owner = "simple-robotics";
  24     repo = "proxsuite";
  25     rev = "v${finalAttrs.version}";
  26     hash = "sha256-iKc55WDHArmmIM//Wir6FHrNV84HnEDcBUlwnsbtMME=";
  27   };
  28
  29   patches = [
  30     # Fix use of system cereal
  31     # This was merged upstream and can be removed on next release
  32     (fetchpatch {
  33       url = "https://github.com/Simple-Robotics/proxsuite/pull/352/commits/8305864f13ca7dff7210f89004a56652b71f8891.patch";
  34       hash = "sha256-XMS/zHFVrEp1P6aDlGrLbrcmuKq42+GdZRH9ObewNCY=";
  35     })
  36   ];
  37
  38   outputs = [
  39     "doc"
  40     "out"
  41   ];
  42
  43   cmakeFlags =
  44     [
  45       (lib.cmakeBool "BUILD_DOCUMENTATION" true)
  46       (lib.cmakeBool "INSTALL_DOCUMENTATION" true)
  47       (lib.cmakeBool "BUILD_PYTHON_INTERFACE" pythonSupport)
  48     ]
  49     ++ lib.optionals (stdenv.hostPlatform.system == "aarch64-linux") [
  50       "-DCMAKE_CTEST_ARGUMENTS=--exclude-regex;ProxQP::dense: test primal infeasibility solving"
  51     ];
  52
  53   strictDeps = true;
  54
  55   nativeBuildInputs = [
  56     cmake
  57     doxygen
  58     graphviz
  59   ] ++ lib.optional pythonSupport python3Packages.pythonImportsCheckHook;
  60   propagatedBuildInputs = [
  61     cereal_1_3_2
  62     eigen
  63     jrl-cmakemodules
  64     simde
  65   ] ++ lib.optionals pythonSupport [ python3Packages.pybind11 ];
  66   checkInputs =
  67     [ matio ]
  68     ++ lib.optionals pythonSupport [
  69       python3Packages.numpy
  70       python3Packages.scipy
  71     ];
  72
  73   # Fontconfig error: Cannot load default config file: No such file: (null)
  74   env.FONTCONFIG_FILE = "${fontconfig.out}/etc/fonts/fonts.conf";
  75
  76   # Fontconfig error: No writable cache directories
  77   preBuild = "export XDG_CACHE_HOME=$(mktemp -d)";
  78
  79   doCheck = true;
  80   pythonImportsCheck = [ "proxsuite" ];
  81
  82   meta = {
  83     description = "The Advanced Proximal Optimization Toolbox";
  84     homepage = "https://github.com/Simple-Robotics/proxsuite";
  85     license = lib.licenses.bsd2;
  86     maintainers = with lib.maintainers; [ nim65s ];
  87     platforms = lib.platforms.unix;
  88   };
  89 })