pkgs/by-name/pt/ptcollab/package.nix

   1 { stdenv
   2 , lib
   3 , fetchFromGitHub
   4 , nix-update-script
   5 , libsForQt5
   6 , libvorbis
   7 , pkg-config
   8 , rtmidi
   9 }:
  10
  11 stdenv.mkDerivation (finalAttrs: {
  12   pname = "ptcollab";
  13   version = "0.6.4.8";
  14
  15   src = fetchFromGitHub {
  16     owner = "yuxshao";
  17     repo = "ptcollab";
  18     rev = "v${finalAttrs.version}";
  19     hash = "sha256-9u2K79QJRfYKL66e1lsRrQMEqmKTWbK+ucal3/u4rP4=";
  20   };
  21
  22   nativeBuildInputs = [
  23     pkg-config
  24   ] ++ (with libsForQt5; [
  25     qmake
  26     qttools
  27     wrapQtAppsHook
  28   ]);
  29
  30   buildInputs = [
  31     libvorbis
  32     rtmidi
  33   ] ++ (with libsForQt5; [
  34     qtbase
  35     qtmultimedia
  36   ]);
  37
  38   postInstall = lib.optionalString stdenv.hostPlatform.isDarwin ''
  39     # Move appbundles to Applications before wrapping happens
  40     mkdir $out/Applications
  41     mv $out/{bin,Applications}/ptcollab.app
  42   '';
  43
  44   postFixup = lib.optionalString stdenv.hostPlatform.isDarwin ''
  45     # Link to now-wrapped binary inside appbundle
  46     ln -s $out/{Applications/ptcollab.app/Contents/MacOS,bin}/ptcollab
  47   '';
  48
  49   passthru = {
  50     updateScript = nix-update-script { };
  51   };
  52
  53   meta = with lib; {
  54     description = "Experimental pxtone editor where you can collaborate with friends";
  55     mainProgram = "ptcollab";
  56     homepage = "https://yuxshao.github.io/ptcollab/";
  57     changelog = "https://github.com/yuxshao/ptcollab/releases/tag/v${finalAttrs.version}";
  58     license = licenses.mit;
  59     maintainers = with maintainers; [ OPNA2608 ];
  60     platforms = platforms.all;
  61   };
  62 })