pkgs/by-name/qa/qadwaitadecorations/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , cmake
   5 , qt5
   6 , qt6
   7 , wayland
   8 , nix-update-script
   9 , useQt6 ? false
  10
  11 # Shadows support on Qt5 requires the feature backported from Qt6:
  12 # https://src.fedoraproject.org/rpms/qt5-qtwayland/blob/rawhide/f/qtwayland-decoration-support-backports-from-qt6.patch
  13 , qt5ShadowsSupport ? false
  14 }:
  15
  16 let
  17   qt = if useQt6 then qt6 else qt5;
  18   qtVersion = if useQt6 then "6" else "5";
  19
  20 in stdenv.mkDerivation (finalAttrs: {
  21   pname = "qadwaitadecorations";
  22   version = "0.1.5";
  23
  24   src = fetchFromGitHub {
  25     owner = "FedoraQt";
  26     repo = "QAdwaitaDecorations";
  27     rev = finalAttrs.version;
  28     hash = "sha256-aqjm93tmBfDkmce1WG5xx8MCDCvo6AOrRHArj/+Ko9E=";
  29   };
  30
  31   nativeBuildInputs = [
  32     cmake
  33   ];
  34
  35   buildInputs = with qt; [
  36     qtbase
  37     qtsvg
  38     qtwayland
  39     wayland
  40   ];
  41
  42   dontWrapQtApps = true;
  43
  44   cmakeFlags = [
  45     "-DQT_PLUGINS_DIR=${placeholder "out"}/${qt.qtbase.qtPluginPrefix}"
  46   ] ++ lib.optional useQt6 "-DUSE_QT6=true"
  47     ++ lib.optional qt5ShadowsSupport "-DHAS_QT6_SUPPORT=true";
  48
  49   passthru.updateScript = nix-update-script { };
  50
  51   meta = {
  52     description = "Qt${qtVersion} Wayland decoration plugin using libadwaita style";
  53     homepage = "https://github.com/FedoraQt/QAdwaitaDecorations";
  54     license = lib.licenses.lgpl21Plus;
  55     maintainers = with lib.maintainers; [ samlukeyes123 ];
  56     platforms = lib.platforms.linux;
  57   };
  58 })