pkgs/by-name/sk/skeema/package.nix

   1 { lib, buildGoModule, fetchFromGitHub, coreutils, testers, skeema }:
   2
   3 buildGoModule rec {
   4   pname = "skeema";
   5   version = "1.12.0";
   6
   7   src = fetchFromGitHub {
   8     owner = "skeema";
   9     repo = "skeema";
  10     rev = "v${version}";
  11     hash = "sha256-MdaMK65PWreIPTuhsm+2ZVRQ8t/wYijkENk8qvX9oEM=";
  12   };
  13
  14   vendorHash = null;
  15
  16   CGO_ENABLED = 0;
  17
  18   ldflags = [ "-s" "-w" ];
  19
  20   preCheck = ''
  21     # Fix tests expecting /usr/bin/printf and /bin/echo
  22     substituteInPlace skeema_cmd_test.go \
  23       --replace /usr/bin/printf "${coreutils}/bin/printf"
  24
  25     substituteInPlace internal/fs/dir_test.go \
  26       --replace /bin/echo "${coreutils}/bin/echo" \
  27       --replace /usr/bin/printf "${coreutils}/bin/printf"
  28
  29     substituteInPlace internal/applier/ddlstatement_test.go \
  30       --replace /bin/echo "${coreutils}/bin/echo"
  31   '';
  32
  33   checkFlags =
  34     let
  35       skippedTests = [
  36         # Tests requiring network access to gitlab.com
  37         "TestDirRelPath"
  38         "TestParseDir"
  39
  40         # Flaky tests
  41         "TestCommandTimeout"
  42         "TestShellOutTimeout"
  43
  44         # Fails with 'internal/fs/testdata/cfgsymlinks1/validrel/.skeema is a symlink pointing outside of its repo'.
  45         "TestParseDirSymlinks"
  46       ];
  47     in
  48     [ "-skip=^${builtins.concatStringsSep "$|^" skippedTests}$" ];
  49
  50   passthru.tests.version = testers.testVersion {
  51     package = skeema;
  52   };
  53
  54   meta = with lib; {
  55     description = "Declarative pure-SQL schema management for MySQL and MariaDB";
  56     homepage = "https://skeema.io/";
  57     license = licenses.asl20;
  58     maintainers = with maintainers; [ aaronjheng ];
  59     mainProgram = "skeema";
  60   };
  61 }