pkgs/by-name/sy/syshud/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   glibmm,
   6   gtk4-layer-shell,
   7   gtkmm4,
   8   libevdev,
   9   nix-update-script,
  10   pkg-config,
  11   wireplumber,
  12   wrapGAppsHook4,
  13 }:
  14
  15 stdenv.mkDerivation (finalAttrs: {
  16   pname = "syshud";
  17   version = "0-unstable-2024-09-26";
  18
  19   src = fetchFromGitHub {
  20     owner = "System64fumo";
  21     repo = "syshud";
  22     rev = "0b6e4958d8ea66b54bc67f0b5aa005fa3eaa4f6f";
  23     hash = "sha256-cyE7ZxesAmnepW7kI6b9Gp7R/v+yG2//EQAj4/X6c+c=";
  24   };
  25
  26   postPatch = ''
  27     substituteInPlace Makefile \
  28       --replace-fail 'pkg-config' ''${PKG_CONFIG}
  29   '';
  30
  31   nativeBuildInputs = [
  32     pkg-config
  33     wrapGAppsHook4
  34   ];
  35
  36   buildInputs = [
  37     glibmm
  38     gtk4-layer-shell
  39     gtkmm4
  40     libevdev
  41     wireplumber
  42   ];
  43
  44   makeFlags = [
  45     "DESTDIR=${placeholder "out"}"
  46     "PREFIX="
  47   ];
  48
  49   # populate version info used by `syshud -v`:
  50   configurePhase = ''
  51     runHook preConfigure
  52
  53     echo '#define GIT_COMMIT_MESSAGE "${finalAttrs.src.rev}"' >> src/git_info.hpp
  54     echo '#define GIT_COMMIT_DATE "${lib.removePrefix "0-unstable-" finalAttrs.version}"' >> src/git_info.hpp
  55
  56     runHook postConfigure
  57   '';
  58
  59   # syshud manually `dlopen`'s its library component
  60   postInstall = ''
  61     wrapProgram $out/bin/syshud --prefix LD_LIBRARY_PATH : $out/lib
  62   '';
  63
  64   passthru.updateScript = nix-update-script {
  65     extraArgs = [
  66       "--version"
  67       "branch"
  68     ];
  69   };
  70
  71   meta = {
  72     description = "simple heads up display written in gtkmm 4";
  73     mainProgram = "syshud";
  74     homepage = "https://github.com/System64fumo/syshud";
  75     license = lib.licenses.wtfpl;
  76     platforms = lib.platforms.linux;
  77     maintainers = with lib.maintainers; [ colinsane ];
  78   };
  79 })