pkgs/by-name/ta/taler-challenger/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchgit,
   5   autoreconfHook,
   6   libgcrypt,
   7   pkg-config,
   8   texinfo,
   9   curl,
  10   gnunet,
  11   jansson,
  12   libgnurl,
  13   libmicrohttpd,
  14   libsodium,
  15   libtool,
  16   postgresql,
  17   taler-exchange,
  18   taler-merchant,
  19   runtimeShell,
  20 }:
  21
  22 stdenv.mkDerivation (finalAttrs: {
  23   pname = "taler-challenger";
  24   version = "0.13.0";
  25
  26   src = fetchgit {
  27     url = "https://git.taler.net/challenger.git";
  28     rev = "v${finalAttrs.version}";
  29     hash = "sha256-OlUgE40Qo7on9VaMGKJ/MRWActDBqPe7Ja95dv1OFhA=";
  30   };
  31
  32   # https://git.taler.net/challenger.git/tree/bootstrap
  33   preAutoreconf = ''
  34     # Generate Makefile.am in contrib/
  35     pushd contrib
  36     rm -f Makefile.am
  37     find wallet-core/challenger/ -type f -printf '  %p \\\n' | sort > Makefile.am.ext
  38     # Remove extra '\' at the end of the file
  39     truncate -s -2 Makefile.am.ext
  40     cat Makefile.am.in Makefile.am.ext >> Makefile.am
  41     # Prevent accidental editing of the generated Makefile.am
  42     chmod -w Makefile.am
  43     popd
  44   '';
  45
  46   strictDeps = true;
  47
  48   nativeBuildInputs = [
  49     autoreconfHook
  50     libgcrypt
  51     pkg-config
  52     texinfo
  53   ];
  54
  55   buildInputs = [
  56     curl
  57     gnunet
  58     jansson
  59     libgcrypt
  60     libgnurl
  61     libmicrohttpd
  62     libsodium
  63     libtool
  64     postgresql
  65     taler-exchange
  66     taler-merchant
  67   ];
  68
  69   preFixup = ''
  70     substituteInPlace $out/bin/challenger-{dbconfig,send-post.sh} \
  71       --replace-fail "/bin/bash" "${runtimeShell}"
  72   '';
  73
  74   meta = {
  75     description = "OAuth 2.0-based authentication service that validates user can receive messages at a certain address";
  76     homepage = "https://git.taler.net/challenger.git";
  77     license = lib.licenses.agpl3Plus;
  78     maintainers = with lib.maintainers; [ wegank ];
  79     platforms = lib.platforms.linux;
  80   };
  81 })