pkgs/by-name/ta/taler-exchange/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchgit,
   5   curl,
   6   gnunet,
   7   jansson,
   8   libgcrypt,
   9   libmicrohttpd,
  10   libsodium,
  11   libunistring,
  12   pkg-config,
  13   postgresql,
  14   autoreconfHook,
  15   python3,
  16   recutils,
  17   wget,
  18   jq,
  19   gettext,
  20   texinfo,
  21 }:
  22
  23 stdenv.mkDerivation (finalAttrs: {
  24   pname = "taler-exchange";
  25   version = "0.13.0";
  26
  27   src = fetchgit {
  28     url = "https://git.taler.net/exchange.git";
  29     rev = "v${finalAttrs.version}";
  30     fetchSubmodules = true;
  31     hash = "sha256-elVZUuiIMLOG058n+Egpy9oD9T2sLDC4TUCYZTCi0bw=";
  32   };
  33
  34   patches = [ ./0001-add-TALER_TEMPLATING_init_path.patch ];
  35
  36   nativeBuildInputs = [
  37     autoreconfHook
  38     pkg-config
  39   ];
  40
  41   buildInputs = [
  42     libgcrypt
  43     libmicrohttpd
  44     jansson
  45     libsodium
  46     postgresql
  47     curl
  48     recutils
  49     gettext
  50     texinfo # Fix 'makeinfo' is missing on your system.
  51     libunistring
  52     python3.pkgs.jinja2
  53     # jq is necessary for some tests and is checked by configure script
  54     jq
  55   ];
  56
  57   propagatedBuildInputs = [ gnunet ];
  58
  59   # From ./bootstrap
  60   preAutoreconf = ''
  61     ./contrib/gana-generate.sh
  62     pushd contrib
  63     rm -f Makefile.am
  64     {
  65       echo 'dist_amlspapkgdata_DATA = \'
  66       find wallet-core/aml-backoffice/ -type f | sort | awk '{print "  " $1 " \\" }'
  67     }  >> Makefile.am.ext
  68     # Remove extra '\' at the end of the file
  69     truncate -s -2 Makefile.am.ext
  70
  71     {
  72       echo ""
  73       echo 'dist_kycspapkgdata_DATA = \'
  74       find wallet-core/kyc/ -type f | sort | awk '{print "  " $1 " \\" }'
  75     }  >> Makefile.am.ext
  76     # Remove extra '\' at the end of the file
  77     truncate -s -2 Makefile.am.ext
  78
  79     {
  80       echo ""
  81       echo 'dist_auditorspapkgdata_DATA = \'
  82       find wallet-core/auditor-backoffice/ -type f | sort | awk '{print "  " $1 " \\" }'
  83     }  >> Makefile.am.ext
  84     # Remove extra '\' at the end of the file
  85     truncate -s -2 Makefile.am.ext
  86
  87     cat Makefile.am.in Makefile.am.ext >> Makefile.am
  88     # Prevent accidental editing of the generated Makefile.am
  89     chmod -w Makefile.am
  90     popd
  91   '';
  92
  93   enableParallelBuilding = true;
  94
  95   doInstallCheck = true;
  96
  97   nativeCheckInputs = [
  98     wget
  99     curl
 100   ];
 101
 102   checkTarget = "check";
 103
 104   meta = {
 105     description = ''
 106       Taler is an electronic payment system providing the ability to pay
 107       anonymously using digital cash.  Taler consists of a network protocol
 108       definition (using a RESTful API over HTTP), a Exchange (which creates
 109       digital coins), a Wallet (which allows customers to manage, store and
 110       spend digital coins), and a Merchant website which allows customers to
 111       spend their digital coins.  Naturally, each Merchant is different, but
 112       Taler includes code examples to help Merchants integrate Taler as a
 113       payment system.
 114     '';
 115     homepage = "https://taler.net/";
 116     changelog = "https://git.taler.net/exchange.git/tree/ChangeLog";
 117     license = lib.licenses.agpl3Plus;
 118     maintainers = with lib.maintainers; [ astro ];
 119     platforms = lib.platforms.linux;
 120   };
 121 })