pkgs/by-name/th/the-powder-toy/package.nix

   1 {
   2   bzip2,
   3   Cocoa,
   4   copyDesktopItems,
   5   curl,
   6   fetchFromGitHub,
   7   fftwFloat,
   8   jsoncpp,
   9   lib,
  10   libpng,
  11   lua,
  12   luajit,
  13   meson,
  14   ninja,
  15   pkg-config,
  16   SDL2,
  17   stdenv,
  18   zlib,
  19 }:
  20 stdenv.mkDerivation rec {
  21   pname = "the-powder-toy";
  22   version = "98.2.365";
  23
  24   src = fetchFromGitHub {
  25     owner = "The-Powder-Toy";
  26     repo = "The-Powder-Toy";
  27     rev = "refs/tags/v${version}";
  28     hash = "sha256-S2aUa25EnUfX6ShW6D+wHrsTLxTcCFcZ/uLE9EWGu4Q=";
  29   };
  30
  31   nativeBuildInputs = [
  32     meson
  33     ninja
  34     pkg-config
  35   ] ++ lib.optional stdenv.hostPlatform.isLinux copyDesktopItems;
  36
  37   buildInputs = [
  38     bzip2
  39     curl
  40     fftwFloat
  41     jsoncpp
  42     libpng
  43     lua
  44     luajit
  45     SDL2
  46     zlib
  47   ] ++ lib.optional stdenv.hostPlatform.isDarwin Cocoa;
  48
  49   mesonFlags = [ "-Dworkaround_elusive_bzip2=false" ];
  50
  51   installPhase = ''
  52     runHook preInstall
  53
  54     install -Dm 755 powder $out/bin/powder
  55
  56     mkdir -p $out/share
  57     mv ../resources $out/share
  58
  59     runHook postInstall
  60   '';
  61
  62   desktopItems = [ "resources/powder.desktop" ];
  63
  64   meta = with lib; {
  65     description = "Free 2D physics sandbox game";
  66     homepage = "https://powdertoy.co.uk/";
  67     platforms = platforms.unix;
  68     license = licenses.gpl3Plus;
  69     maintainers = with maintainers; [
  70       abbradar
  71       siraben
  72     ];
  73     mainProgram = "powder";
  74   };
  75 }