pkgs/by-name/uu/uuu/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , nix-update-script
   5
   6 , cmake
   7 , installShellFiles
   8 , pkg-config
   9
  10 , bzip2
  11 , libusb1
  12 , openssl
  13 , tinyxml-2
  14 , zlib
  15 , zstd
  16 }:
  17
  18 stdenv.mkDerivation (finalAttrs: {
  19   pname = "uuu";
  20   version = "1.5.182";
  21
  22   src = fetchFromGitHub {
  23     owner = "nxp-imx";
  24     repo = "mfgtools";
  25     rev = "uuu_${finalAttrs.version}";
  26     hash = "sha256-I0EX+vsaOwz+HJUWFC5Z/xRu6xegzEfmuAlBd/OSAp4=";
  27   };
  28
  29   passthru.updateScript = nix-update-script {
  30     extraArgs = [ "--version-regex" "uuu_\([0-9.]+\)" ];
  31   };
  32
  33   nativeBuildInputs = [
  34     cmake
  35     installShellFiles
  36     pkg-config
  37   ];
  38
  39   buildInputs = [
  40     bzip2
  41     libusb1
  42     openssl
  43     tinyxml-2
  44     zlib
  45     zstd
  46   ];
  47
  48   postPatch = ''
  49     # Avoid the need of calling Git during the build.
  50     echo "uuu_${finalAttrs.version}" > .tarball-version
  51   '';
  52
  53   postInstall = ''
  54     installShellCompletion --bash --name uuu.bash ${./completion.bash}
  55
  56     mkdir -p $out/lib/udev/rules.d
  57     cat <($out/bin/uuu -udev) > $out/lib/udev/rules.d/70-uuu.rules
  58   '';
  59
  60   meta = with lib; {
  61     description = "Freescale/NXP I.MX Chip image deploy tools";
  62     homepage = "https://github.com/nxp-imx/mfgtools";
  63     license = licenses.bsd3;
  64     maintainers = with maintainers; [ otavio ];
  65     mainProgram = "uuu";
  66     platforms = platforms.all;
  67   };
  68 })