pkgs/by-name/ux/uxn/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromSourcehut
   4 , SDL2
   5 , unstableGitUpdater
   6 }:
   7
   8 stdenv.mkDerivation (finalAttrs: {
   9   pname = "uxn";
  10   version = "1.0-unstable-2024-09-20";
  11
  12   src = fetchFromSourcehut {
  13     owner = "~rabbits";
  14     repo = "uxn";
  15     rev = "f8c53f59b012dd56d44ae50cdf90dd1dad6cce23";
  16     hash = "sha256-Ee4hN3OnqF/OhKieGtzT4XOhNJIhywCgP6Us0DZTVBI=";
  17   };
  18
  19   outputs = [ "out" "projects" ];
  20
  21   nativeBuildInputs = [
  22     SDL2
  23   ];
  24
  25   buildInputs = [
  26     SDL2
  27   ];
  28
  29   strictDeps = true;
  30
  31   postPatch = ''
  32     patchShebangs build.sh
  33     substituteInPlace build.sh \
  34       --replace "-L/usr/local/lib " ""
  35   '';
  36
  37   buildPhase = ''
  38     runHook preBuild
  39
  40     ./build.sh --no-run
  41
  42     runHook postBuild
  43   '';
  44
  45   # ./build.sh --install is meant to install in $HOME, therefore not useful for
  46   # package maintainers
  47   installPhase = ''
  48     runHook preInstall
  49
  50     install -d $out/bin/
  51     cp bin/uxnasm bin/uxncli bin/uxnemu $out/bin/
  52     install -d $projects/share/uxn/
  53     cp -r projects $projects/share/uxn/
  54
  55     runHook postInstall
  56   '';
  57
  58   passthru.updateScript = unstableGitUpdater { };
  59
  60   meta = {
  61     homepage = "https://wiki.xxiivv.com/site/uxn.html";
  62     description = "Assembler and emulator for the Uxn stack machine";
  63     license = lib.licenses.mit;
  64     maintainers = with lib.maintainers; [ AndersonTorres ];
  65     mainProgram = "uxnemu";
  66     inherit (SDL2.meta) platforms;
  67     broken = stdenv.hostPlatform.isDarwin;
  68   };
  69 })