pkgs/by-name/ve/ventoy/package.nix

   1 { lib
   2 , autoPatchelfHook
   3 , bash
   4 , copyDesktopItems
   5 , coreutils
   6 , cryptsetup
   7 , dosfstools
   8 , e2fsprogs
   9 , exfat
  10 , fetchurl
  11 , gawk
  12 , gnugrep
  13 , gnused
  14 , gtk3
  15 , hexdump
  16 , makeDesktopItem
  17 , makeWrapper
  18 , ntfs3g
  19 , parted
  20 , procps
  21 , stdenv
  22 , util-linux
  23 , which
  24 , xfsprogs
  25 , xz
  26 , defaultGuiType ? ""
  27 , withCryptsetup ? false
  28 , withXfs ? false
  29 , withExt4 ? false
  30 , withNtfs ? false
  31 , withGtk3 ? false
  32 , withQt5 ? false
  33 , libsForQt5
  34 }:
  35
  36 assert lib.elem defaultGuiType [ "" "gtk3" "qt5" ];
  37 assert defaultGuiType == "gtk3" -> withGtk3;
  38 assert defaultGuiType == "qt5" -> withQt5;
  39
  40 let
  41   inherit (lib) optionals optionalString;
  42   inherit (libsForQt5) qtbase wrapQtAppsHook;
  43   arch = {
  44     x86_64-linux = "x86_64";
  45     i686-linux = "i386";
  46     aarch64-linux = "aarch64";
  47     mipsel-linux = "mips64el";
  48   }.${stdenv.hostPlatform.system}
  49     or (throw "Unsupported platform: ${stdenv.hostPlatform.system}");
  50 in
  51 stdenv.mkDerivation (finalAttrs: {
  52   pname = "ventoy";
  53   version = "1.0.99";
  54
  55   src = fetchurl {
  56     url = "https://github.com/ventoy/Ventoy/releases/download/v${finalAttrs.version}/ventoy-${finalAttrs.version}-linux.tar.gz";
  57     hash = "sha256-RnzdGIp/c5vHBq28HWlfYf/e/JWRatsBWUfYCCnwCj0=";
  58   };
  59
  60   patches = [
  61     ./000-nixos-sanitization.patch
  62   ];
  63
  64   postPatch = ''
  65     # Fix permissions.
  66     find -type f -name \*.sh -exec chmod a+x '{}' \;
  67
  68     # Fix path to log.
  69     sed -i 's:log\.txt:/var/log/ventoy\.log:g' \
  70         WebUI/static/js/languages.js tool/languages.json
  71   '';
  72
  73   nativeBuildInputs = [
  74     autoPatchelfHook
  75     makeWrapper
  76   ]
  77   ++ optionals (withQt5 || withGtk3) [ copyDesktopItems ]
  78   ++ optionals withQt5 [ wrapQtAppsHook ];
  79
  80   buildInputs = [
  81     bash
  82     coreutils
  83     dosfstools
  84     exfat
  85     gawk
  86     gnugrep
  87     gnused
  88     hexdump
  89     parted
  90     procps
  91     util-linux
  92     which
  93     xz
  94   ]
  95   ++ optionals withCryptsetup [ cryptsetup ]
  96   ++ optionals withExt4 [ e2fsprogs ]
  97   ++ optionals withGtk3 [ gtk3 ]
  98   ++ optionals withNtfs [ ntfs3g ]
  99   ++ optionals withXfs [ xfsprogs ]
 100   ++ optionals withQt5 [ qtbase ];
 101
 102   strictDeps = true;
 103
 104   desktopItems = [
 105     (makeDesktopItem {
 106       name = "Ventoy";
 107       desktopName = "Ventoy";
 108       comment = "Tool to create bootable USB drive for ISO/WIM/IMG/VHD(x)/EFI files";
 109       icon = "VentoyLogo";
 110       exec = "ventoy-gui";
 111       terminal = false;
 112       categories = [ "Utility" ];
 113       startupNotify = true;
 114     })
 115   ];
 116
 117   dontConfigure = true;
 118   dontBuild = true;
 119
 120   installPhase = ''
 121     runHook preInstall
 122
 123     # Setup variables
 124     local VENTOY_PATH="$out"/share/ventoy
 125     local ARCH='${arch}'
 126
 127     # Prepare
 128     cd tool/"$ARCH"
 129     rm ash* hexdump* mkexfatfs* mount.exfat-fuse* xzcat*
 130     for archive in *.xz; do
 131         xzcat "$archive" > "''${archive%.xz}"
 132         rm "$archive"
 133     done
 134     chmod a+x *
 135     cd -
 136
 137     # Cleanup.
 138     case "$ARCH" in
 139         x86_64) rm -r {tool/,VentoyGUI.}{i386,aarch64,mips64el};;
 140         i386) rm -r {tool/,VentoyGUI.}{x86_64,aarch64,mips64el};;
 141         aarch64) rm -r {tool/,VentoyGUI.}{x86_64,i386,mips64el};;
 142         mips64el) rm -r {tool/,VentoyGUI.}{x86_64,i386,aarch64};;
 143     esac
 144     rm README
 145     rm tool/"$ARCH"/Ventoy2Disk.gtk2 || true  # For aarch64 and mips64el.
 146
 147     # Copy from "$src" to "$out"
 148     mkdir -p "$out"/bin "$VENTOY_PATH"
 149     cp -r . "$VENTOY_PATH"
 150
 151     # Fill bin dir
 152     for f in Ventoy2Disk.sh_ventoy VentoyWeb.sh_ventoy-web \
 153              CreatePersistentImg.sh_ventoy-persistent \
 154              ExtendPersistentImg.sh_ventoy-extend-persistent \
 155              VentoyPlugson.sh_ventoy-plugson; do
 156         local bin="''${f%_*}" wrapper="''${f#*_}"
 157         makeWrapper "$VENTOY_PATH/$bin" "$out/bin/$wrapper" \
 158                     --prefix PATH : "${lib.makeBinPath finalAttrs.buildInputs}" \
 159                     --chdir "$VENTOY_PATH"
 160     done
 161   ''
 162   # VentoGUI uses the `ventoy_gui_type` file to determine the type of GUI.
 163   # See: https://github.com/ventoy/Ventoy/blob/v1.0.78/LinuxGUI/Ventoy2Disk/ventoy_gui.c#L1096
 164   + optionalString (withGtk3 || withQt5) ''
 165     echo "${defaultGuiType}" > "$VENTOY_PATH/ventoy_gui_type"
 166     makeWrapper "$VENTOY_PATH/VentoyGUI.$ARCH" "$out/bin/ventoy-gui" \
 167                 --prefix PATH : "${lib.makeBinPath finalAttrs.buildInputs}" \
 168                 --chdir "$VENTOY_PATH"
 169     mkdir "$out"/share/{applications,pixmaps}
 170     ln -s "$VENTOY_PATH"/WebUI/static/img/VentoyLogo.png "$out"/share/pixmaps/
 171   ''
 172   + optionalString (!withGtk3) ''
 173     rm "$VENTOY_PATH"/tool/{"$ARCH"/Ventoy2Disk.gtk3,VentoyGTK.glade}
 174   ''
 175   + optionalString (!withQt5) ''
 176     rm "$VENTOY_PATH/tool/$ARCH/Ventoy2Disk.qt5"
 177   ''
 178   + optionalString (!withGtk3 && !withQt5) ''
 179     rm "$VENTOY_PATH"/VentoyGUI.*
 180   '' +
 181   ''
 182
 183     runHook postInstall
 184   '';
 185
 186   meta = {
 187     homepage = "https://www.ventoy.net";
 188     description = "New Bootable USB Solution";
 189     longDescription = ''
 190       Ventoy is an open source tool to create bootable USB drive for
 191       ISO/WIM/IMG/VHD(x)/EFI files.  With ventoy, you don't need to format the
 192       disk over and over, you just need to copy the ISO/WIM/IMG/VHD(x)/EFI files
 193       to the USB drive and boot them directly. You can copy many files at a time
 194       and ventoy will give you a boot menu to select them. You can also browse
 195       ISO/WIM/IMG/VHD(x)/EFI files in local disk and boot them. x86 Legacy
 196       BIOS, IA32 UEFI, x86_64 UEFI, ARM64 UEFI and MIPS64EL UEFI are supported
 197       in the same way.  Most type of OS supported
 198       (Windows/WinPE/Linux/ChromeOS/Unix/VMware/Xen...).  With ventoy you can
 199       also browse ISO/WIM/IMG/VHD(x)/EFI files in local disk and boot them.
 200       800+ image files are tested.  90%+ distros in DistroWatch supported.
 201     '';
 202     changelog = "https://www.ventoy.net/doc_news.html";
 203     license = lib.licenses.gpl3Plus;
 204     mainProgram = "ventoy";
 205     maintainers = with lib.maintainers; [ AndersonTorres ];
 206     platforms = [ "x86_64-linux" "i686-linux" "aarch64-linux" "mipsel-linux" ];
 207     sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
 208   };
 209 })