pkgs/by-name/wt/wtwitch/package.nix

   1 { bash
   2 , coreutils-prefixed
   3 , curl
   4 , fetchFromGitHub
   5 , gnused
   6 , gnugrep
   7 , installShellFiles
   8 , jq
   9 , lib
  10 , makeWrapper
  11 , mplayer
  12 , mpv
  13 , procps
  14 , scdoc
  15 , stdenv
  16 , streamlink
  17 , vlc
  18 }:
  19
  20 stdenv.mkDerivation rec {
  21   pname = "wtwitch";
  22   version = "2.6.3";
  23
  24   src = fetchFromGitHub {
  25     owner = "krathalan";
  26     repo = pname;
  27     rev = version;
  28     hash = "sha256-2YLBuxGwGkav3zB2qMqM6yRXf7ZLqgULoJV4s5p+hSw=";
  29   };
  30
  31   # hardcode SCRIPT_NAME because #150841
  32   postPatch = ''
  33     substituteInPlace src/wtwitch --replace 'readonly SCRIPT_NAME="''${0##*/}"' 'readonly SCRIPT_NAME="wtwitch"'
  34   '';
  35
  36   buildPhase = ''
  37     scdoc < src/wtwitch.1.scd > wtwitch.1
  38   '';
  39
  40   nativeBuildInputs = [ scdoc installShellFiles makeWrapper ];
  41
  42   installPhase = ''
  43     installManPage wtwitch.1
  44     installShellCompletion --cmd wtwitch \
  45       --bash src/wtwitch-completion.bash \
  46       --zsh src/_wtwitch
  47     install -Dm755 src/wtwitch $out/bin/wtwitch
  48     wrapProgram $out/bin/wtwitch \
  49       --set-default LANG en_US.UTF-8 \
  50       --prefix PATH : ${lib.makeBinPath (lib.optionals stdenv.hostPlatform.isLinux [ vlc ] ++ [
  51         bash
  52         coreutils-prefixed
  53         curl
  54         gnused
  55         gnugrep
  56         jq
  57         mplayer
  58         mpv
  59         procps
  60         streamlink
  61       ])}
  62   '';
  63
  64   meta = with lib; {
  65     description = "Terminal user interface for Twitch";
  66     homepage = "https://github.com/krathalan/wtwitch";
  67     license = licenses.gpl3Only;
  68     maintainers = with maintainers; [ urandom ];
  69     platforms = platforms.all;
  70     mainProgram = "wtwitch";
  71   };
  72 }