pkgs/by-name/ya/yabai/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   overrideSDK,
   5   fetchFromGitHub,
   6   fetchzip,
   7   installShellFiles,
   8   testers,
   9   writeShellScript,
  10   common-updater-scripts,
  11   curl,
  12   darwin,
  13   jq,
  14   xcodebuild,
  15   xxd,
  16   yabai,
  17 }:
  18 let
  19   inherit (darwin.apple_sdk_11_0.frameworks)
  20     Carbon
  21     Cocoa
  22     ScriptingBridge
  23     SkyLight
  24     ;
  25
  26   stdenv' = if stdenv.hostPlatform.isDarwin then overrideSDK stdenv "11.0" else stdenv;
  27 in
  28 stdenv'.mkDerivation (finalAttrs: {
  29   pname = "yabai";
  30   version = "7.1.3";
  31
  32   src =
  33     finalAttrs.passthru.sources.${stdenv.hostPlatform.system}
  34       or (throw "Unsupported system: ${stdenv.hostPlatform.system}");
  35
  36   env = {
  37     # silence service.h error
  38     NIX_CFLAGS_COMPILE = "-Wno-implicit-function-declaration";
  39   };
  40
  41   nativeBuildInputs =
  42     [ installShellFiles ]
  43     ++ lib.optionals stdenv.hostPlatform.isx86_64 [
  44       xcodebuild
  45       xxd
  46     ];
  47
  48   buildInputs = lib.optionals stdenv.hostPlatform.isx86_64 [
  49     Carbon
  50     Cocoa
  51     ScriptingBridge
  52     SkyLight
  53   ];
  54
  55   dontConfigure = true;
  56   dontBuild = stdenv.hostPlatform.isAarch64;
  57   enableParallelBuilding = true;
  58
  59   installPhase = ''
  60     runHook preInstall
  61
  62     mkdir -p $out/{bin,share/icons/hicolor/scalable/apps}
  63
  64     cp ./bin/yabai $out/bin/yabai
  65     ${lib.optionalString stdenv.hostPlatform.isx86_64 "cp ./assets/icon/icon.svg $out/share/icons/hicolor/scalable/apps/yabai.svg"}
  66     installManPage ./doc/yabai.1
  67
  68     runHook postInstall
  69   '';
  70
  71   postPatch =
  72     lib.optionalString stdenv.hostPlatform.isx86_64 # bash
  73       ''
  74         # aarch64 code is compiled on all targets, which causes our Apple SDK headers to error out.
  75         # Since multilib doesn't work on darwin i dont know of a better way of handling this.
  76         substituteInPlace makefile \
  77         --replace "-arch arm64e" "" \
  78         --replace "-arch arm64" "" \
  79         --replace "clang" "${stdenv.cc.targetPrefix}clang"
  80
  81         # `NSScreen::safeAreaInsets` is only available on macOS 12.0 and above, which frameworks aren't packaged.
  82         # When a lower OS version is detected upstream just returns 0, so we can hardcode that at compile time.
  83         # https://github.com/koekeishiya/yabai/blob/v4.0.2/src/workspace.m#L109
  84         substituteInPlace src/workspace.m \
  85         --replace 'return screen.safeAreaInsets.top;' 'return 0;'
  86       '';
  87
  88   passthru = {
  89     tests.version = testers.testVersion {
  90       package = yabai;
  91       version = "yabai-v${finalAttrs.version}";
  92     };
  93
  94     sources = {
  95       # Unfortunately compiling yabai from source on aarch64-darwin is a bit complicated. We use the precompiled binary instead for now.
  96       # See the comments on https://github.com/NixOS/nixpkgs/pull/188322 for more information.
  97       "aarch64-darwin" = fetchzip {
  98         url = "https://github.com/koekeishiya/yabai/releases/download/v${finalAttrs.version}/yabai-v${finalAttrs.version}.tar.gz";
  99         hash = "sha256-wp5B24DYX1RYHS/3+4WRRCzVE6FyCzatJDpzJWrEIpQ=";
 100       };
 101       "x86_64-darwin" = fetchFromGitHub {
 102         owner = "koekeishiya";
 103         repo = "yabai";
 104         rev = "v${finalAttrs.version}";
 105         hash = "sha256-hCwI6ziUR4yuJOv4MQXh3ufbausaDrG8XfjR+jIOeC4=";
 106       };
 107     };
 108
 109     updateScript = writeShellScript "update-yabai" ''
 110       set -o errexit
 111       export PATH="${
 112         lib.makeBinPath [
 113           curl
 114           jq
 115           common-updater-scripts
 116         ]
 117       }"
 118       NEW_VERSION=$(curl --silent https://api.github.com/repos/koekeishiya/yabai/releases/latest | jq '.tag_name | ltrimstr("v")' --raw-output)
 119       if [[ "${finalAttrs.version}" = "$NEW_VERSION" ]]; then
 120           echo "The new version same as the old version."
 121           exit 0
 122       fi
 123       for platform in ${lib.escapeShellArgs finalAttrs.meta.platforms}; do
 124         update-source-version "yabai" "$NEW_VERSION" --ignore-same-version --source-key="sources.$platform"
 125       done
 126     '';
 127   };
 128
 129   meta = {
 130     description = "Tiling window manager for macOS based on binary space partitioning";
 131     longDescription = ''
 132       yabai is a window management utility that is designed to work as an extension to the built-in
 133       window manager of macOS. yabai allows you to control your windows, spaces and displays freely
 134       using an intuitive command line interface and optionally set user-defined keyboard shortcuts
 135       using skhd and other third-party software.
 136     '';
 137     homepage = "https://github.com/koekeishiya/yabai";
 138     changelog = "https://github.com/koekeishiya/yabai/blob/v${finalAttrs.version}/CHANGELOG.md";
 139     license = lib.licenses.mit;
 140     platforms = builtins.attrNames finalAttrs.passthru.sources;
 141     mainProgram = "yabai";
 142     maintainers = with lib.maintainers; [
 143       cmacrae
 144       shardy
 145       khaneliman
 146     ];
 147     sourceProvenance =
 148       with lib.sourceTypes;
 149       lib.optionals stdenv.hostPlatform.isx86_64 [ fromSource ]
 150       ++ lib.optionals stdenv.hostPlatform.isAarch64 [ binaryNativeCode ];
 151   };
 152 })