pkgs/by-name/zu/zunit/package.nix

   1 {
   2   lib,
   3   stdenvNoCC,
   4   fetchFromGitHub,
   5   zsh,
   6   revolver,
   7   installShellFiles,
   8   testers,
   9   nix-update-script,
  10 }:
  11
  12 stdenvNoCC.mkDerivation (finalAttrs: {
  13   pname = "zunit";
  14   version = "0.8.2";
  15
  16   src = fetchFromGitHub {
  17     owner = "zunit-zsh";
  18     repo = "zunit";
  19     rev = "v${finalAttrs.version}";
  20     hash = "sha256-GkBewb795piCaniZJZpGEZFhKaNs8p8swV5z34OegPY=";
  21     deepClone = true; # Needed in order to get "tests" folder
  22   };
  23
  24   strictDeps = true;
  25   doCheck = true;
  26   doInstallCheck = true;
  27
  28   nativeBuildInputs = [
  29     zsh
  30     installShellFiles
  31   ];
  32   nativeCheckInputs = [ revolver ];
  33   buildInputs = [
  34     zsh
  35     revolver
  36   ];
  37
  38   postPatch = ''
  39     for i in $(find src/ -type f -print); do
  40       substituteInPlace $i \
  41         --replace-warn " revolver " " ${lib.getExe revolver} "
  42     done
  43   '';
  44
  45   buildPhase = ''
  46     runHook preBuild
  47
  48     zsh build.zsh
  49
  50     runHook postBuild
  51   '';
  52
  53   checkPhase = ''
  54     runHook preCheck
  55
  56     HOME="$TEMPDIR" zsh zunit
  57
  58     runHook postCheck
  59   '';
  60
  61   installPhase = ''
  62     runHook preInstall
  63
  64     install -Dm755 zunit $out/bin/zunit
  65
  66     runHook postInstall
  67   '';
  68
  69   postInstall = ''
  70     installShellCompletion --cmd zunit --zsh zunit.zsh-completion
  71   '';
  72
  73   installCheckPhase = ''
  74     runHook preInstallCheck
  75
  76     PATH=$PATH:$out/bin zunit --help
  77
  78     runHook postInstallCheck
  79   '';
  80
  81   passthru = {
  82     tests.version = testers.testVersion { package = finalAttrs.finalPackage; };
  83     updateScript = nix-update-script { };
  84   };
  85
  86   meta = {
  87     description = "Powerful testing framework for ZSH projects";
  88     homepage = "https://zunit.xyz/";
  89     downloadPage = "https://github.com/zunit-zsh/zunit/releases";
  90     changelog = "https://github.com/zunit-zsh/zunit/releases/tag/${finalAttrs.src.rev}";
  91     license = lib.licenses.mit;
  92     mainProgram = "zunit";
  93     inherit (zsh.meta) platforms;
  94     maintainers = with lib.maintainers; [ d-brasher ];
  95   };
  96 })