pkgs/os-specific/darwin/bartender/default.nix

   1 { lib
   2 , stdenvNoCC
   3 , fetchurl
   4 , _7zz
   5 }:
   6
   7 stdenvNoCC.mkDerivation (finalAttrs: {
   8   pname = "bartender";
   9   version = "5.1.8";
  10
  11   src = fetchurl {
  12     name = "Bartender ${lib.versions.major finalAttrs.version}.dmg";
  13     url = "https://www.macbartender.com/B2/updates/${builtins.replaceStrings [ "." ] [ "-" ] finalAttrs.version}/Bartender%20${lib.versions.major finalAttrs.version}.dmg";
  14     hash = "sha256-8ypSGbgnfbUv1zZlEihBjiW3UEwU8GwBT4FGiuEpLfU=";
  15   };
  16
  17   dontPatch = true;
  18   dontConfigure = true;
  19   dontBuild = true;
  20   dontFixup = true;
  21
  22   nativeBuildInputs = [ _7zz ];
  23
  24   sourceRoot = "Bartender ${lib.versions.major finalAttrs.version}.app";
  25
  26   installPhase = ''
  27     runHook preInstall
  28
  29     mkdir -p "$out/Applications/${finalAttrs.sourceRoot}"
  30     cp -R . "$out/Applications/${finalAttrs.sourceRoot}"
  31
  32     runHook postInstall
  33   '';
  34
  35   meta = {
  36     description = "Take control of your menu bar";
  37     longDescription = ''
  38       Bartender is an award-winning app for macOS that superpowers your menu bar, giving you total control over your menu bar items, what's displayed, and when, with menu bar items only showing when you need them.
  39       Bartender improves your workflow with quick reveal, search, custom hotkeys and triggers, and lots more.
  40     '';
  41     homepage = "https://www.macbartender.com";
  42     changelog = "https://www.macbartender.com/Bartender${lib.versions.major finalAttrs.version}/release_notes/";
  43     license = [ lib.licenses.unfree ];
  44     sourceProvenance = [ lib.sourceTypes.binaryNativeCode ];
  45     maintainers = with lib.maintainers; [ stepbrobd DimitarNestorov ];
  46     platforms = [ "aarch64-darwin" "x86_64-darwin" ];
  47   };
  48 })