pkgs/build-support/ocaml/dune.nix

   1 { lib, stdenv, ocaml, findlib, dune_1, dune_2, dune_3 }:
   2
   3 { pname, version, nativeBuildInputs ? [], enableParallelBuilding ? true, ... }@args:
   4
   5 let Dune =
   6   let dune-version = args.duneVersion or "3"; in
   7   { "1" = dune_1; "2" = dune_2; "3" = dune_3; }."${dune-version}"
   8 ; in
   9
  10 if (args ? minimumOCamlVersion && lib.versionOlder ocaml.version args.minimumOCamlVersion) ||
  11    (args ? minimalOCamlVersion && lib.versionOlder ocaml.version args.minimalOCamlVersion)
  12 then throw "${pname}-${version} is not available for OCaml ${ocaml.version}"
  13 else
  14
  15 stdenv.mkDerivation ({
  16
  17   inherit enableParallelBuilding;
  18   dontAddStaticConfigureFlags = true;
  19   configurePlatforms = [];
  20
  21   buildPhase = ''
  22     runHook preBuild
  23     dune build -p ${pname} ''${enableParallelBuilding:+-j $NIX_BUILD_CORES}
  24     runHook postBuild
  25   '';
  26   checkPhase = ''
  27     runHook preCheck
  28     dune runtest -p ${pname} ''${enableParallelBuilding:+-j $NIX_BUILD_CORES}
  29     runHook postCheck
  30   '';
  31   installPhase = ''
  32     runHook preInstall
  33     dune install --prefix $out --libdir $OCAMLFIND_DESTDIR ${pname} \
  34      ${if lib.versionAtLeast Dune.version "2.9"
  35        then "--docdir $out/share/doc --mandir $out/share/man"
  36        else ""}
  37     runHook postInstall
  38   '';
  39
  40   strictDeps = true;
  41
  42 } // (builtins.removeAttrs args [ "minimalOCamlVersion" "duneVersion" ]) // {
  43
  44   name = "ocaml${ocaml.version}-${pname}-${version}";
  45
  46   nativeBuildInputs = [ ocaml Dune findlib ] ++ nativeBuildInputs;
  47
  48   meta = (args.meta or {}) // { platforms = args.meta.platforms or ocaml.meta.platforms; };
  49
  50 })