pkgs/build-support/release/debian-build.nix

   1 # This function compiles a source tarball in a virtual machine image
   2 # that contains a Debian-like (i.e. dpkg-based) OS.
   3
   4 { name ? "debian-build"
   5 , diskImage
   6 , src, lib, stdenv, vmTools, checkinstall
   7 , fsTranslation ? false
   8 , # Features provided by this package.
   9   debProvides ? []
  10 , # Features required by this package.
  11   debRequires ? []
  12 , ... } @ args:
  13
  14 vmTools.runInLinuxImage (stdenv.mkDerivation (
  15
  16   {
  17     doCheck = true;
  18
  19     prefix = "/usr";
  20
  21     prePhases = "installExtraDebsPhase sysInfoPhase";
  22   }
  23
  24   // removeAttrs args ["vmTools" "lib"] //
  25
  26   {
  27     name = name + "-" + diskImage.name + (lib.optionalString (src ? version) "-${src.version}");
  28
  29     # !!! cut&paste from rpm-build.nix
  30     postHook = ''
  31       . ${./functions.sh}
  32       propagateImageName
  33       src=$(findTarball $src)
  34     '';
  35
  36     installExtraDebsPhase = ''
  37       for i in $extraDebs; do
  38         dpkg --install $(ls $i/debs/*.deb | sort | head -1)
  39       done
  40     '';
  41
  42     sysInfoPhase = ''
  43       [ ! -f /etc/lsb-release ] || (source /etc/lsb-release; echo "OS release: $DISTRIB_DESCRIPTION")
  44       echo "System/kernel: $(uname -a)"
  45       if test -e /etc/debian_version; then echo "Debian release: $(cat /etc/debian_version)"; fi
  46       echo "installed Debian packages"
  47       dpkg-query --list
  48     '';
  49
  50     installPhase = ''
  51       eval "$preInstall"
  52       export LOGNAME=root
  53
  54       # otherwise build hangs when it wants to display
  55       # the log file
  56       export PAGER=cat
  57       ${checkinstall}/sbin/checkinstall --nodoc -y -D \
  58         --fstrans=${if fsTranslation then "yes" else "no"} \
  59         --requires="${lib.concatStringsSep "," debRequires}" \
  60         --provides="${lib.concatStringsSep "," debProvides}" \
  61         ${if (src ? version) then "--pkgversion=$(echo ${src.version} | tr _ -)"
  62                              else "--pkgversion=0.0.0"} \
  63         ''${debMaintainer:+--maintainer="'$debMaintainer'"} \
  64         ''${debName:+--pkgname="'$debName'"} \
  65         $checkInstallFlags \
  66         -- \
  67         $SHELL -c "''${installCommand:-make install}"
  68
  69       mkdir -p $out/debs
  70       find . -name "*.deb" -exec cp {} $out/debs \;
  71
  72       [ "$(echo $out/debs/*.deb)" != "" ]
  73
  74       for i in $out/debs/*.deb; do
  75         echo "Generated DEB package: $i"
  76         dpkg-deb --info "$i"
  77         pkgName=$(dpkg-deb -W "$i" | awk '{print $1}')
  78         echo "file deb $i" >> $out/nix-support/hydra-build-products
  79       done
  80       dpkg -i $out/debs/*.deb
  81
  82       for i in $extraDebs; do
  83         echo "file deb-extra $(ls $i/debs/*.deb | sort | head -1)" >> $out/nix-support/hydra-build-products
  84       done
  85
  86       eval "$postInstall"
  87     '';
  88
  89     meta = (lib.optionalAttrs (args ? meta) args.meta) // {
  90       description = "Deb package for ${diskImage.fullName}";
  91     };
  92   }
  93
  94 ))