pkgs/games/openra_2019/engine.nix

   1 /*  The package defintion for an OpenRA engine.
   2     It shares code with `mod.nix` by what is defined in `common.nix`.
   3     Similar to `mod.nix` it is a generic package definition,
   4     in order to make it easy to define multiple variants of the OpenRA engine.
   5     For each mod provided by the engine, a wrapper script is created,
   6     matching the naming convention used by `mod.nix`.
   7     This package could be seen as providing a set of in-tree mods,
   8     while the `mod.nix` pacakges provide a single out-of-tree mod.
   9 */
  10 { lib, stdenv
  11 , packageAttrs
  12 , patchEngine
  13 , wrapLaunchGame
  14 , engine
  15 }:
  16
  17 stdenv.mkDerivation (lib.recursiveUpdate packageAttrs rec {
  18   pname = "openra_2019";
  19   version = "${engine.name}-${engine.version}";
  20
  21   src = engine.src;
  22
  23   postPatch = patchEngine "." version;
  24
  25   configurePhase = ''
  26     runHook preConfigure
  27
  28     make version VERSION=${lib.escapeShellArg version}
  29
  30     runHook postConfigure
  31   '';
  32
  33   buildFlags = [ "DEBUG=false" "default" "man-page" ];
  34
  35   checkTarget = "nunit test";
  36
  37   installTargets = [
  38     "install"
  39     "install-linux-icons"
  40     "install-linux-desktop"
  41     "install-linux-appdata"
  42     "install-linux-mime"
  43     "install-man-page"
  44   ];
  45
  46   postInstall = ''
  47     ${wrapLaunchGame "" "openra"}
  48
  49     ${lib.concatStrings (map (mod: ''
  50       makeWrapper $out/bin/openra $out/bin/openra-${mod} --add-flags Game.Mod=${mod}
  51     '') engine.mods)}
  52   '';
  53
  54   meta = {
  55     inherit (engine) description homepage;
  56   };
  57 })