pkgs/tools/misc/fd/default.nix

   1 { lib, rustPlatform, fetchFromGitHub, installShellFiles, rust-jemalloc-sys, testers, fd }:
   2
   3 rustPlatform.buildRustPackage rec {
   4   pname = "fd";
   5   version = "10.1.0";
   6
   7   src = fetchFromGitHub {
   8     owner = "sharkdp";
   9     repo = "fd";
  10     rev = "v${version}";
  11     hash = "sha256-9fL2XV3Vre2uo8Co3tlHYIvpNHNOh5TuvZggkWOxm5A=";
  12   };
  13
  14   cargoHash = "sha256-3TbsPfAn/GcGASc0RCcyAeUiD4RUtvTATdTYhKdBxvo=";
  15
  16   nativeBuildInputs = [ installShellFiles ];
  17
  18   buildInputs = [ rust-jemalloc-sys ];
  19
  20   # skip flaky test
  21   checkFlags = [
  22     "--skip=test_owner_current_group"
  23     # Fails if the filesystem performs UTF-8 validation (such as ZFS with utf8only=on)
  24     "--skip=test_exec_invalid_utf8"
  25     "--skip=test_invalid_utf8"
  26   ];
  27
  28   postInstall = ''
  29     installManPage doc/fd.1
  30
  31     installShellCompletion --cmd fd \
  32       --bash <($out/bin/fd --gen-completions bash) \
  33       --fish <($out/bin/fd --gen-completions fish)
  34     installShellCompletion --zsh contrib/completion/_fd
  35   '';
  36
  37   passthru.tests.version = testers.testVersion {
  38     package = fd;
  39   };
  40
  41   meta = with lib; {
  42     description = "A simple, fast and user-friendly alternative to find";
  43     longDescription = ''
  44       `fd` is a simple, fast and user-friendly alternative to `find`.
  45
  46       While it does not seek to mirror all of `find`'s powerful functionality,
  47       it provides sensible (opinionated) defaults for 80% of the use cases.
  48     '';
  49     homepage = "https://github.com/sharkdp/fd";
  50     changelog = "https://github.com/sharkdp/fd/blob/v${version}/CHANGELOG.md";
  51     license = with licenses; [ asl20 /* or */ mit ];
  52     maintainers = with maintainers; [ dywedir figsoda globin ma27 zowoq ];
  53     mainProgram = "fd";
  54   };
  55 }