doc/using/overrides.chapter.md

   1 # Overriding {#chap-overrides}
   2
   3 Sometimes one wants to override parts of `nixpkgs`, e.g. derivation attributes, the results of derivations.
   4
   5 These functions are used to make changes to packages, returning only single packages. [Overlays](#chap-overlays), on the other hand, can be used to combine the overridden packages across the entire package set of Nixpkgs.
   6
   7 ## &lt;pkg&gt;.override {#sec-pkg-override}
   8
   9 The function `override` is usually available for all the derivations in the nixpkgs expression (`pkgs`).
  10
  11 It is used to override the arguments passed to a function.
  12
  13 Example usages:
  14
  15 ```nix
  16 pkgs.foo.override { arg1 = val1; arg2 = val2; /* ... */ }
  17 ```
  18
  19 It's also possible to access the previous arguments.
  20
  21 ```nix
  22 pkgs.foo.override (previous: { arg1 = previous.arg1; /* ... */ })
  23 ```
  24
  25 <!-- TODO: move below programlisting to a new section about extending and overlays and reference it -->
  26
  27 ```nix
  28 import pkgs.path { overlays = [ (self: super: {
  29   foo = super.foo.override { barSupport = true ; };
  30   })];}
  31 ```
  32
  33 ```nix
  34 {
  35   mypkg = pkgs.callPackage ./mypkg.nix {
  36     mydep = pkgs.mydep.override { /* ... */ };
  37   };
  38 }
  39 ```
  40
  41 In the first example, `pkgs.foo` is the result of a function call with some default arguments, usually a derivation. Using `pkgs.foo.override` will call the same function with the given new arguments.
  42
  43 Many packages, like the `foo` example above, provide package options with default values in their arguments, to facilitate overriding.
  44 Because it's not usually feasible to test that packages build with all combinations of options, you might find that a package doesn't build if you override options to non-default values.
  45
  46 Package maintainers are not expected to fix arbitrary combinations of options.
  47 If you find that something doesn't work, please submit a fix, ideally with a regression test.
  48 If you want to ensure that things keep working, consider [becoming a maintainer](https://github.com/NixOS/nixpkgs/tree/master/maintainers) for the package.
  49
  50 ## &lt;pkg&gt;.overrideAttrs {#sec-pkg-overrideAttrs}
  51
  52 The function `overrideAttrs` allows overriding the attribute set passed to a `stdenv.mkDerivation` call, producing a new derivation based on the original one. This function is available on all derivations produced by the `stdenv.mkDerivation` function, which is most packages in the nixpkgs expression `pkgs`.
  53
  54 Example usages:
  55
  56 ```nix
  57 {
  58   helloBar = pkgs.hello.overrideAttrs (finalAttrs: previousAttrs: {
  59     pname = previousAttrs.pname + "-bar";
  60   });
  61 }
  62 ```
  63
  64 In the above example, "-bar" is appended to the pname attribute, while all other attributes will be retained from the original `hello` package.
  65
  66 The argument `previousAttrs` is conventionally used to refer to the attr set originally passed to `stdenv.mkDerivation`.
  67
  68 The argument `finalAttrs` refers to the final attributes passed to `mkDerivation`, plus the `finalPackage` attribute which is equal to the result of `mkDerivation` or subsequent `overrideAttrs` calls.
  69
  70 If only a one-argument function is written, the argument has the meaning of `previousAttrs`.
  71
  72 Function arguments can be omitted entirely if there is no need to access `previousAttrs` or `finalAttrs`.
  73
  74 ```nix
  75 {
  76   helloWithDebug = pkgs.hello.overrideAttrs {
  77     separateDebugInfo = true;
  78   };
  79 }
  80 ```
  81
  82 In the above example, the `separateDebugInfo` attribute is overridden to be true, thus building debug info for `helloWithDebug`.
  83
  84 ::: {.note}
  85 Note that `separateDebugInfo` is processed only by the `stdenv.mkDerivation` function, not the generated, raw Nix derivation. Thus, using `overrideDerivation` will not work in this case, as it overrides only the attributes of the final derivation. It is for this reason that `overrideAttrs` should be preferred in (almost) all cases to `overrideDerivation`, i.e. to allow using `stdenv.mkDerivation` to process input arguments, as well as the fact that it is easier to use (you can use the same attribute names you see in your Nix code, instead of the ones generated (e.g. `buildInputs` vs `nativeBuildInputs`), and it involves less typing).
  86 :::
  87
  88 ## &lt;pkg&gt;.overrideDerivation {#sec-pkg-overrideDerivation}
  89
  90 ::: {.warning}
  91 You should prefer `overrideAttrs` in almost all cases, see its documentation for the reasons why. `overrideDerivation` is not deprecated and will continue to work, but is less nice to use and does not have as many abilities as `overrideAttrs`.
  92 :::
  93
  94 ::: {.warning}
  95 Do not use this function in Nixpkgs as it evaluates a derivation before modifying it, which breaks package abstraction. In addition, this evaluation-per-function application incurs a performance penalty, which can become a problem if many overrides are used. It is only intended for ad-hoc customisation, such as in `~/.config/nixpkgs/config.nix`.
  96 :::
  97
  98 The function `overrideDerivation` creates a new derivation based on an existing one by overriding the original's attributes with the attribute set produced by the specified function. This function is available on all derivations defined using the `makeOverridable` function. Most standard derivation-producing functions, such as `stdenv.mkDerivation`, are defined using this function, which means most packages in the nixpkgs expression, `pkgs`, have this function.
  99
 100 Example usage:
 101
 102 ```nix
 103 {
 104   mySed = pkgs.gnused.overrideDerivation (oldAttrs: {
 105     name = "sed-4.2.2-pre";
 106     src = fetchurl {
 107       url = "ftp://alpha.gnu.org/gnu/sed/sed-4.2.2-pre.tar.bz2";
 108       hash = "sha256-MxBJRcM2rYzQYwJ5XKxhXTQByvSg5jZc5cSHEZoB2IY=";
 109     };
 110     patches = [];
 111   });
 112 }
 113 ```
 114
 115 In the above example, the `name`, `src`, and `patches` of the derivation will be overridden, while all other attributes will be retained from the original derivation.
 116
 117 The argument `oldAttrs` is used to refer to the attribute set of the original derivation.
 118
 119 ::: {.note}
 120 A package's attributes are evaluated *before* being modified by the `overrideDerivation` function. For example, the `name` attribute reference in `url = "mirror://gnu/hello/${name}.tar.gz";` is filled-in *before* the `overrideDerivation` function modifies the attribute set. This means that overriding the `name` attribute, in this example, *will not* change the value of the `url` attribute. Instead, we need to override both the `name` *and* `url` attributes.
 121 :::
 122
 123 ## lib.makeOverridable {#sec-lib-makeOverridable}
 124
 125 The function `lib.makeOverridable` is used to make the result of a function easily customizable. This utility only makes sense for functions that accept an argument set and return an attribute set.
 126
 127 Example usage:
 128
 129 ```nix
 130 {
 131   f = { a, b }: { result = a+b; };
 132   c = lib.makeOverridable f { a = 1; b = 2; };
 133 }
 134 ```
 135
 136 The variable `c` is the value of the `f` function applied with some default arguments. Hence the value of `c.result` is `3`, in this example.
 137
 138 The variable `c` however also has some additional functions, like
 139 [c.override](#sec-pkg-override) which can be used to override the
 140 default arguments. In this example the value of
 141 `(c.override { a = 4; }).result` is 6.