pkgs/applications/terminal-emulators/rio/default.nix

   1 { lib
   2 , stdenv
   3 , darwin
   4 , fetchFromGitHub
   5 , rustPlatform
   6 , nixosTests
   7 , nix-update-script
   8
   9 , autoPatchelfHook
  10 , cmake
  11 , ncurses
  12 , pkg-config
  13
  14 , gcc-unwrapped
  15 , fontconfig
  16 , libGL
  17 , vulkan-loader
  18 , libxkbcommon
  19
  20 , withX11 ? !stdenv.hostPlatform.isDarwin
  21 , libX11
  22 , libXcursor
  23 , libXi
  24 , libXrandr
  25 , libxcb
  26
  27 , withWayland ? !stdenv.hostPlatform.isDarwin
  28 , wayland
  29
  30 , testers
  31 , rio
  32 }:
  33 let
  34   rlinkLibs = if stdenv.hostPlatform.isDarwin then [
  35     darwin.libobjc
  36     darwin.apple_sdk_11_0.frameworks.AppKit
  37     darwin.apple_sdk_11_0.frameworks.AVFoundation
  38     darwin.apple_sdk_11_0.frameworks.MetalKit
  39     darwin.apple_sdk_11_0.frameworks.Vision
  40   ] else [
  41     (lib.getLib gcc-unwrapped)
  42     fontconfig
  43     libGL
  44     libxkbcommon
  45     vulkan-loader
  46   ] ++ lib.optionals withX11 [
  47     libX11
  48     libXcursor
  49     libXi
  50     libXrandr
  51     libxcb
  52   ] ++ lib.optionals withWayland [
  53     wayland
  54   ];
  55 in
  56 rustPlatform.buildRustPackage rec {
  57   pname = "rio";
  58   version = "0.1.17";
  59
  60   src = fetchFromGitHub {
  61     owner = "raphamorim";
  62     repo = "rio";
  63     rev = "v${version}";
  64     hash = "sha256-10E7tIuix0BGKFbADLhcReRC01FXV/dBivJjfSe/X/c=";
  65   };
  66
  67   cargoHash = "sha256-yGOvY5+ThSey/k8ilTTC0CzaOIJtc4hDYmdrHJC3HyE=";
  68
  69   nativeBuildInputs = [
  70     ncurses
  71   ] ++ lib.optionals stdenv.hostPlatform.isLinux [
  72     cmake
  73     pkg-config
  74     autoPatchelfHook
  75   ];
  76
  77   runtimeDependencies = rlinkLibs;
  78
  79   buildInputs = rlinkLibs;
  80
  81   outputs = [ "out" "terminfo" ];
  82
  83   buildNoDefaultFeatures = true;
  84   buildFeatures = [ ]
  85     ++ lib.optional withX11 "x11"
  86     ++ lib.optional withWayland "wayland";
  87
  88   checkFlags = [
  89     # Fail to run in sandbox environment.
  90     "--skip=sys::unix::eventedfd::EventedFd"
  91   ];
  92
  93   postInstall = ''
  94     install -D -m 644 misc/rio.desktop -t $out/share/applications
  95     install -D -m 644 misc/logo.svg \
  96                       $out/share/icons/hicolor/scalable/apps/rio.svg
  97
  98     install -dm 755 "$terminfo/share/terminfo/r/"
  99     tic -xe rio,rio-direct -o "$terminfo/share/terminfo" misc/rio.terminfo
 100     mkdir -p $out/nix-support
 101     echo "$terminfo" >> $out/nix-support/propagated-user-env-packages
 102   '' + lib.optionalString stdenv.hostPlatform.isDarwin ''
 103     mkdir $out/Applications/
 104     mv misc/osx/Rio.app/ $out/Applications/
 105     mkdir $out/Applications/Rio.app/Contents/MacOS/
 106     ln -s $out/bin/rio $out/Applications/Rio.app/Contents/MacOS/
 107   '';
 108
 109   passthru = {
 110     updateScript = nix-update-script {
 111       extraArgs = [ "--version-regex" "v([0-9.]+)" ];
 112     };
 113
 114     tests = {
 115       version = testers.testVersion { package = rio; };
 116     } // lib.optionalAttrs stdenv.buildPlatform.isLinux {
 117       # FIXME: Restrict test execution inside nixosTests for Linux devices as ofborg
 118       # 'passthru.tests' nixosTests are failing on Darwin architectures.
 119       #
 120       # Ref: https://github.com/NixOS/nixpkgs/issues/345825
 121       test = nixosTests.terminal-emulators.rio;
 122     };
 123   };
 124
 125   meta = {
 126     description = "Hardware-accelerated GPU terminal emulator powered by WebGPU";
 127     homepage = "https://raphamorim.io/rio";
 128     license = lib.licenses.mit;
 129     maintainers = with lib.maintainers; [ tornax otavio oluceps ];
 130     platforms = lib.platforms.unix;
 131     changelog = "https://github.com/raphamorim/rio/blob/v${version}/docs/docs/releases.md";
 132     mainProgram = "rio";
 133   };
 134 }