pkgs/development/python-modules/pyeclib/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   buildPythonPackage,
   5   distutils,
   6   fetchFromGitHub,
   7   liberasurecode,
   8   pytestCheckHook,
   9   setuptools,
  10   six,
  11 }:
  12
  13 buildPythonPackage rec {
  14   pname = "pyeclib";
  15   version = "1.6.1";
  16   pyproject = true;
  17
  18   src = fetchFromGitHub {
  19     owner = "openstack";
  20     repo = "pyeclib";
  21     rev = "refs/tags/${version}";
  22     hash = "sha256-pa3majZ68+DQGtgGCpZVRshof+w9jvpxreo4dkckLXk=";
  23   };
  24
  25   postPatch = ''
  26     # patch dlopen call
  27     substituteInPlace src/c/pyeclib_c/pyeclib_c.c \
  28       --replace-fail "liberasurecode.so" "${liberasurecode}/lib/liberasurecode.so"
  29
  30     # python's platform.platform() doesn't return "Darwin" (anymore?)
  31     substituteInPlace setup.py \
  32       --replace-fail '"Darwin"' '"macOS"'
  33   '';
  34
  35   build-system = [
  36     distutils
  37     setuptools
  38   ];
  39
  40   preBuild =
  41     let
  42       ldLibraryPathEnvName =
  43         if stdenv.hostPlatform.isDarwin then "DYLD_LIBRARY_PATH" else "LD_LIBRARY_PATH";
  44     in
  45     ''
  46       # required for the custom _find_library function in setup.py
  47       export ${ldLibraryPathEnvName}="${lib.makeLibraryPath [ liberasurecode ]}"
  48     '';
  49
  50   dependencies = [ liberasurecode ];
  51
  52   nativeCheckInputs = [
  53     pytestCheckHook
  54     six
  55   ];
  56
  57   pythonImportsCheck = [ "pyeclib" ];
  58
  59   meta = with lib; {
  60     description = "This library provides a simple Python interface for implementing erasure codes";
  61     homepage = "https://github.com/openstack/pyeclib";
  62     license = licenses.bsd2;
  63     maintainers = teams.openstack.members;
  64   };
  65 }