pkgs/by-name/an/ani-skip/package.nix

   1 {
   2   stdenvNoCC,
   3   fetchFromGitHub,
   4   makeWrapper,
   5   gnugrep,
   6   gnused,
   7   curl,
   8   fzf,
   9   lib,
  10 }:
  11 stdenvNoCC.mkDerivation (finalAttrs: {
  12   pname = "ani-skip";
  13   version = "1.0.1";
  14
  15   src = fetchFromGitHub {
  16     owner = "synacktraa";
  17     repo = "ani-skip";
  18     rev = "refs/tags/${finalAttrs.version}";
  19     hash = "sha256-VEEG3d6rwTAS7/+gBKHFKIg9zFfBu5eBOu6Z23621gM=";
  20   };
  21
  22   nativeBuildInputs = [ makeWrapper ];
  23   runtimeInputs = [
  24     gnugrep
  25     gnused
  26     curl
  27     fzf
  28   ];
  29
  30   installPhase = ''
  31     runHook preInstall
  32
  33     install -D skip.lua $out/share/mpv/scripts/skip.lua
  34     install -Dm 755 ani-skip $out/bin/ani-skip
  35
  36     runHook postInstall
  37   '';
  38
  39   postFixup = ''
  40     substituteInPlace $out/bin/ani-skip \
  41       --replace-fail '--script-opts=%s' "--script=$out/share/mpv/scripts/skip.lua --script-opts=%s"
  42
  43     wrapProgram $out/bin/ani-skip \
  44       --prefix PATH : ${lib.makeBinPath finalAttrs.runtimeInputs}
  45   '';
  46
  47   meta = {
  48     homepage = "https://github.com/synacktraa/ani-skip";
  49     description = "Automated solution to bypassing anime opening and ending sequences";
  50     mainProgram = "ani-skip";
  51     license = lib.licenses.gpl3;
  52     maintainers = [ lib.maintainers.diniamo ];
  53     platforms = lib.platforms.unix;
  54   };
  55 })