pkgs/by-name/au/autorandr/package.nix

   1 { lib
   2 , python3
   3 , fetchFromGitHub
   4 , systemd
   5 , xrandr
   6 , installShellFiles
   7 , desktop-file-utils
   8 }:
   9
  10 python3.pkgs.buildPythonApplication rec {
  11   pname = "autorandr";
  12   version = "1.15";
  13   format = "other";
  14
  15   src = fetchFromGitHub {
  16     owner = "phillipberndt";
  17     repo = "autorandr";
  18     rev = "refs/tags/${version}";
  19     hash = "sha256-8FMfy3GCN4z/TnfefU2DbKqV3W35I29/SuGGqeOrjNg";
  20   };
  21
  22   nativeBuildInputs = [ installShellFiles desktop-file-utils ];
  23   propagatedBuildInputs = with python3.pkgs; [ packaging ];
  24
  25   buildPhase = ''
  26     substituteInPlace autorandr.py \
  27       --replace 'os.popen("xrandr' 'os.popen("${xrandr}/bin/xrandr' \
  28       --replace '["xrandr"]' '["${xrandr}/bin/xrandr"]'
  29   '';
  30
  31   patches = [ ./0001-don-t-use-sys.executable.patch ];
  32
  33   outputs = [ "out" "man" ];
  34
  35   installPhase = ''
  36     runHook preInstall
  37     make install TARGETS='autorandr' PREFIX=$out
  38
  39     # zsh completions exist but currently have no make target, use
  40     # installShellCompletions for both
  41     # see https://github.com/phillipberndt/autorandr/issues/197
  42     installShellCompletion --cmd autorandr \
  43         --bash contrib/bash_completion/autorandr \
  44         --zsh contrib/zsh_completion/_autorandr \
  45         --fish contrib/fish_completion/autorandr.fish
  46
  47     make install TARGETS='autostart_config' PREFIX=$out DESTDIR=$out
  48
  49     make install TARGETS='manpage' PREFIX=$man
  50
  51     ${if systemd != null then ''
  52       make install TARGETS='systemd udev' PREFIX=$out DESTDIR=$out \
  53         SYSTEMD_UNIT_DIR=/lib/systemd/system \
  54         UDEV_RULES_DIR=/etc/udev/rules.d
  55       substituteInPlace $out/etc/udev/rules.d/40-monitor-hotplug.rules \
  56         --replace /bin/systemctl "/run/current-system/systemd/bin/systemctl"
  57     '' else ''
  58       make install TARGETS='pmutils' DESTDIR=$out \
  59         PM_SLEEPHOOKS_DIR=/lib/pm-utils/sleep.d
  60       make install TARGETS='udev' PREFIX=$out DESTDIR=$out \
  61         UDEV_RULES_DIR=/etc/udev/rules.d
  62     ''}
  63
  64     runHook postInstall
  65   '';
  66
  67   meta = with lib; {
  68     homepage = "https://github.com/phillipberndt/autorandr/";
  69     description = "Automatically select a display configuration based on connected devices";
  70     license = licenses.gpl3Plus;
  71     maintainers = with maintainers; [ coroa ];
  72     platforms = platforms.unix;
  73     mainProgram = "autorandr";
  74   };
  75 }