pkgs/by-name/bo/boost-build/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , bison
   5 # boost derivation to use for the src and version.
   6 # This is used by the boost derivation to build
   7 # a b2 matching their version (by overriding this
   8 # argument). Infinite recursion is not an issue
   9 # since we only look at src and version of boost.
  10 , useBoost ? {}
  11 }:
  12
  13 let
  14   defaultVersion = "4.4.1";
  15 in
  16
  17 stdenv.mkDerivation {
  18   pname = "boost-build";
  19   version =
  20     if useBoost ? version
  21     then "boost-${useBoost.version}"
  22     else defaultVersion;
  23
  24   src = useBoost.src or (fetchFromGitHub {
  25     owner = "boostorg";
  26     repo = "build";
  27     rev = defaultVersion;
  28     sha256 = "1r4rwlq87ydmsdqrik4ly5iai796qalvw7603mridg2nwcbbnf54";
  29   });
  30
  31   # b2 is in a subdirectory of boost source tarballs
  32   postUnpack = lib.optionalString (useBoost ? src) ''
  33     sourceRoot="$sourceRoot/tools/build"
  34   '';
  35
  36   patches = useBoost.boostBuildPatches or []
  37     ++ lib.optional (useBoost ? version && lib.versionAtLeast useBoost.version "1.81") ./fix-clang-target.patch;
  38
  39   postPatch = lib.optionalString (useBoost ? version && lib.versionAtLeast useBoost.version "1.80") ''
  40     # Upstream uses arm64, but nixpkgs uses aarch64.
  41     substituteInPlace src/tools/clang.jam \
  42       --replace-fail 'arch = arm64' 'arch = aarch64'
  43   '' + lib.optionalString (useBoost ? version && lib.versionOlder useBoost.version "1.77") ''
  44     substituteInPlace src/build-system.jam \
  45       --replace-fail "default-toolset = darwin" "default-toolset = clang-darwin"
  46   '' + lib.optionalString (useBoost ? version && lib.versionAtLeast useBoost.version "1.82") ''
  47     patchShebangs --build src/engine/build.sh
  48   '';
  49
  50   nativeBuildInputs = [
  51     bison
  52   ];
  53
  54   buildPhase = ''
  55     runHook preBuild
  56     ./bootstrap.sh
  57     runHook postBuild
  58   '';
  59
  60   installPhase = ''
  61     runHook preInstall
  62
  63     ./b2 ${lib.optionalString (stdenv.cc.isClang) "toolset=clang "}install --prefix="$out"
  64
  65     # older versions of b2 created this symlink,
  66     # which we want to support building via useBoost.
  67     test -e "$out/bin/bjam" || ln -s b2 "$out/bin/bjam"
  68
  69     runHook postInstall
  70   '';
  71
  72   meta = with lib; {
  73     homepage = "https://www.boost.org/build/";
  74     license = lib.licenses.boost;
  75     platforms = platforms.unix;
  76     maintainers = with maintainers; [ ivan-tkatchev ];
  77   };
  78 }