pkgs/by-name/ca/cartridges/package.nix

   1 {
   2   lib,
   3   appstream,
   4   blueprint-compiler,
   5   desktop-file-utils,
   6   fetchFromGitHub,
   7   glib,
   8   glib-networking,
   9   gobject-introspection,
  10   gtk4,
  11   libadwaita,
  12   meson,
  13   ninja,
  14   pkg-config,
  15   python3Packages,
  16   wrapGAppsHook4,
  17 }:
  18
  19 python3Packages.buildPythonApplication rec {
  20   pname = "cartridges";
  21   version = "2.10.1";
  22   pyproject = false;
  23
  24   src = fetchFromGitHub {
  25     owner = "kra-mo";
  26     repo = "cartridges";
  27     rev = "refs/tags/v${version}";
  28     hash = "sha256-uwU0jW5+33hiqpuG83r0GVfANl6ltDLa3s4s0IJHRoQ=";
  29   };
  30
  31   strictDeps = true;
  32
  33   nativeBuildInputs = [
  34     appstream
  35     blueprint-compiler
  36     desktop-file-utils # for `desktop-file-validate`
  37     glib # for `glib-compile-schemas`
  38     gtk4 # for `gtk-update-icon-cache`
  39     gobject-introspection
  40     meson
  41     ninja
  42     pkg-config
  43     wrapGAppsHook4
  44   ];
  45
  46   buildInputs = [
  47     glib-networking
  48     libadwaita
  49   ];
  50
  51   dependencies = with python3Packages; [
  52     pillow
  53     pygobject3
  54     pyyaml
  55     requests
  56   ];
  57
  58   dontWrapGApps = true;
  59   makeWrapperArgs = [ "\${gappsWrapperArgs[@]}" ];
  60
  61   postFixup = ''
  62     wrapPythonProgramsIn $out/libexec $out $pythonPath
  63   '';
  64
  65   # NOTE: `postCheck` is intentionally not used here, as the entire checkPhase
  66   # is skipped by `buildPythonApplication`
  67   # https://github.com/NixOS/nixpkgs/blob/9d4343b7b27a3e6f08fc22ead568233ff24bbbde/pkgs/development/interpreters/python/mk-python-derivation.nix#L296
  68   postInstallCheck = ''
  69     mesonCheckPhase
  70   '';
  71
  72   meta = {
  73     description = "GTK4 + Libadwaita game launcher";
  74     longDescription = ''
  75       A simple game launcher for all of your games.
  76       It has support for importing games from Steam, Lutris, Heroic
  77       and more with no login necessary.
  78       You can sort and hide games or download cover art from SteamGridDB.
  79     '';
  80     homepage = "https://apps.gnome.org/Cartridges/";
  81     changelog = "https://github.com/kra-mo/cartridges/releases/tag/${version}";
  82     license = lib.licenses.gpl3Plus;
  83     maintainers = with lib.maintainers; [ getchoo ];
  84     mainProgram = "cartridges";
  85     platforms = lib.platforms.linux;
  86   };
  87 }