pkgs/by-name/ci/cider-2/package.nix

   1 {
   2   appimageTools,
   3   lib,
   4   requireFile,
   5   makeWrapper,
   6 }:
   7
   8 appimageTools.wrapType2 rec {
   9   pname = "cider-2";
  10   version = "2.5.0";
  11
  12   src = requireFile {
  13     name = "Cider-linux-appimage-x64.AppImage";
  14     url = "https://cidercollective.itch.io/cider";
  15     sha256 = "1nm35psq9ddii2c15kb03ifcn43fimvc4yzb4cpm1gqsiz4w21qz";
  16   };
  17
  18   nativeBuildInputs = [ makeWrapper ];
  19
  20   extraInstallCommands =
  21     let
  22       contents = appimageTools.extract {
  23         inherit version src;
  24         # HACK: this looks for a ${pname}.desktop, where `cider-2.desktop` doesn't exist
  25         pname = "cider";
  26       };
  27     in
  28     ''
  29       wrapProgram $out/bin/${pname} \
  30          --add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations}}" \
  31          --add-flags "--no-sandbox --disable-gpu-sandbox" # Cider 2 does not start up properly without these from my preliminary testing
  32
  33       install -m 444 -D ${contents}/cider.desktop $out/share/applications/${pname}.desktop
  34       substituteInPlace $out/share/applications/${pname}.desktop \
  35         --replace-warn 'Exec=AppRun --no-sandbox' 'Exec=${pname}'
  36       cp -r ${contents}/usr/share/icons $out/share
  37     '';
  38
  39   meta = {
  40     description = "Powerful music player that allows you listen to your favorite tracks with style";
  41     homepage = "https://cider.sh";
  42     license = lib.licenses.unfree;
  43     mainProgram = "cider-2";
  44     maintainers = with lib.maintainers; [ itsvic-dev ];
  45     platforms = [ "x86_64-linux" ];
  46   };
  47 }