pkgs/by-name/ci/circt/package.nix

   1 {
   2   stdenv,
   3   lib,
   4   cmake,
   5   coreutils,
   6   python3,
   7   git,
   8   fetchFromGitHub,
   9   ninja,
  10   lit,
  11   z3,
  12   gitUpdater,
  13   callPackage,
  14 }:
  15
  16 let
  17   pythonEnv = python3.withPackages (ps: [ ps.psutil ]);
  18   circt-llvm = callPackage ./circt-llvm.nix { };
  19 in
  20 stdenv.mkDerivation rec {
  21   pname = "circt";
  22   version = "1.87.0";
  23   src = fetchFromGitHub {
  24     owner = "llvm";
  25     repo = "circt";
  26     rev = "firtool-${version}";
  27     hash = "sha256-buWpoym57YxyHJySYaektAUmuSRXMS+YBwtjWpoV1Vg=";
  28     fetchSubmodules = true;
  29   };
  30
  31   requiredSystemFeatures = [ "big-parallel" ];
  32
  33   nativeBuildInputs = [
  34     cmake
  35     ninja
  36     git
  37     pythonEnv
  38     z3
  39   ];
  40   buildInputs = [ circt-llvm ];
  41
  42   cmakeFlags = [
  43     "-DBUILD_SHARED_LIBS=ON"
  44     "-DMLIR_DIR=${circt-llvm.dev}/lib/cmake/mlir"
  45
  46     # LLVM_EXTERNAL_LIT is executed by python3, the wrapped bash script will not work
  47     "-DLLVM_EXTERNAL_LIT=${lit}/bin/.lit-wrapped"
  48     "-DCIRCT_LLHD_SIM_ENABLED=OFF"
  49   ];
  50
  51   # cannot use lib.optionalString as it creates an empty string, disabling all tests
  52   LIT_FILTER_OUT =
  53     let
  54       lit-filters =
  55         # There are some tests depending on `clang-tools` to work. They are activated only when detected
  56         # `clang-tidy` in PATH, However, we cannot simply put `clang-tools` in checkInputs to make these
  57         # tests work. Because
  58         #
  59         # 1. The absolute paths of binaries used in tests are resolved in configure phase.
  60         # 2. When stdenv = clangStdenv, the `clang-tidy` binary appears in PATH via `clang-unwrapped`,
  61         #    which is always placed before `${clang-tools}/bin` in PATH. `clang-tidy` provided in
  62         #    `clang-unwrapped` cause tests failing because it is not wrapped to resolve header search paths.
  63         #    https://github.com/NixOS/nixpkgs/issues/214945 discusses this issue.
  64         #
  65         # As a temporary fix, we disabled these tests when using clang stdenv
  66         lib.optionals stdenv.cc.isClang [ "CIRCT :: Target/ExportSystemC/.*\.mlir" ]
  67         # Disable some tests on x86_64-darwin
  68         ++ lib.optionals (stdenv.hostPlatform.system == "x86_64-darwin") [
  69           # These test seem to pass on hydra (rosetta) but not on x86_64-darwin machines
  70           "CIRCT :: Target/ExportSMTLIB/attributes.mlir"
  71           "CIRCT :: Target/ExportSMTLIB/basic.mlir"
  72           "CIRCT :: circt-bmc/comb-errors.mlir"
  73           "CIRCT :: circt-bmc/seq-errors.mlir"
  74           # This test was having issues with rosetta
  75           "CIRCT :: Dialect/SMT/basic.mlir"
  76         ];
  77     in
  78     if lit-filters != [ ] then lib.strings.concatStringsSep "|" lit-filters else null;
  79
  80   preConfigure = ''
  81     find ./test -name '*.mlir' -exec sed -i 's|/usr/bin/env|${coreutils}/bin/env|g' {} \;
  82     # circt uses git to check its version, but when cloned on nix it can't access git.
  83     # So this hard codes the version.
  84     substituteInPlace cmake/modules/GenVersionFile.cmake \
  85       --replace-fail "unknown git version" "${src.rev}"
  86     # Increase timeout on tests because some were failing on hydra.
  87     # Using `replace-warn` so it doesn't break when upstream changes the timeout.
  88     substituteInPlace integration_test/CMakeLists.txt \
  89       --replace-warn 'set(CIRCT_INTEGRATION_TIMEOUT 60)' 'set(CIRCT_INTEGRATION_TIMEOUT 300)'
  90   '';
  91
  92   doCheck = true;
  93   checkTarget = "check-circt check-circt-integration";
  94
  95   preCheck = lib.optionalString stdenv.hostPlatform.isDarwin ''
  96     echo moving libarc-jit-env.dylib to '$lib' before check because archilator links to the output path
  97     mkdir -pv $lib/lib
  98     cp -v ./lib/libarc-jit-env.dylib $lib/lib
  99   '';
 100
 101   outputs = [
 102     "out"
 103     "lib"
 104     "dev"
 105   ];
 106
 107   # Copy circt-llvm's postFixup stage so that it can make all our dylib references
 108   # absolute as well.
 109   #
 110   # We don't need `postPatch` because circt seems to be automatically inheriting
 111   # the config somehow, presumably via. `-DMLIR_DIR`.
 112   postFixup = circt-llvm.postFixup;
 113
 114   postInstall = ''
 115     moveToOutput lib "$lib"
 116   '';
 117
 118   passthru = {
 119     updateScript = gitUpdater {
 120       rev-prefix = "firtool-";
 121     };
 122     llvm = circt-llvm;
 123   };
 124
 125   meta = {
 126     description = "Circuit IR compilers and tools";
 127     homepage = "https://circt.org/";
 128     license = lib.licenses.asl20;
 129     maintainers = with lib.maintainers; [
 130       sharzy
 131       pineapplehunter
 132       sequencer
 133     ];
 134     platforms = lib.platforms.all;
 135   };
 136 }