pkgs/by-name/do/dooit/package.nix

   1 {
   2   lib,
   3   fetchFromGitHub,
   4   dooit,
   5   python311,
   6   testers,
   7   nix-update-script,
   8 }:
   9 let
  10   python3 = python311;
  11 in
  12 python3.pkgs.buildPythonApplication rec {
  13   pname = "dooit";
  14   version = "2.2.0";
  15   pyproject = true;
  16
  17   src = fetchFromGitHub {
  18     owner = "kraanzu";
  19     repo = "dooit";
  20     rev = "v${version}";
  21     hash = "sha256-GtXRzj+o+FClleh73kqelk0JrSyafZhf847lX1BiS9k=";
  22   };
  23
  24   build-system = with python3.pkgs; [ poetry-core ];
  25
  26   pythonRelaxDeps = [
  27     "tzlocal"
  28   ];
  29
  30   propagatedBuildInputs = with python3.pkgs; [
  31     appdirs
  32     pyperclip
  33     python-dateutil
  34     pyyaml
  35     (textual.overridePythonAttrs (oldAttrs: {
  36       version = "0.47.1";
  37       src = fetchFromGitHub {
  38         owner = "Textualize";
  39         repo = "textual";
  40         rev = "refs/tags/v0.47.1";
  41         hash = "sha256-RFaZKQ+0o6ZvfZxx95a1FjSHVJ0VOIAfzkdxYQXYBKU=";
  42       };
  43       disabledTests = [
  44         "test_tracked_slugs"
  45         "test_textual_env_var"
  46         "test_register_language"
  47         "test_register_language_existing_language"
  48       ];
  49     }))
  50     tzlocal
  51   ];
  52
  53   # No tests available
  54   doCheck = false;
  55
  56   passthru = {
  57     tests.version = testers.testVersion {
  58       package = dooit;
  59       command = "HOME=$(mktemp -d) dooit --version";
  60     };
  61
  62     updateScript = nix-update-script { };
  63   };
  64
  65   meta = with lib; {
  66     description = "TUI todo manager";
  67     homepage = "https://github.com/kraanzu/dooit";
  68     changelog = "https://github.com/kraanzu/dooit/blob/v${version}/CHANGELOG.md";
  69     license = licenses.mit;
  70     maintainers = with maintainers; [
  71       khaneliman
  72       wesleyjrz
  73       kraanzu
  74     ];
  75     mainProgram = "dooit";
  76   };
  77 }