pkgs/by-name/en/envision/package.nix

   1 {
   2   buildFHSEnv,
   3   envision-unwrapped,
   4 }:
   5
   6 buildFHSEnv {
   7   name = "envision";
   8
   9   extraOutputsToInstall = [ "dev" ];
  10
  11   strictDeps = true;
  12
  13   # TODO: I'm pretty suspicious of this list of additonal required dependencies. Are they all really needed?
  14   targetPkgs =
  15     pkgs:
  16     [ pkgs.envision-unwrapped ]
  17     ++ (with pkgs; [
  18       stdenv.cc.libc
  19       gcc
  20     ])
  21     ++ (
  22       # OpenHMD dependencies
  23       pkgs.openhmd.buildInputs ++ pkgs.openhmd.nativeBuildInputs
  24     )
  25     ++ (
  26       # OpenComposite dependencies
  27       pkgs.opencomposite.buildInputs ++ pkgs.opencomposite.nativeBuildInputs
  28     )
  29     ++ (
  30       # Monado dependencies
  31       (
  32         pkgs.monado.buildInputs
  33         ++ pkgs.monado.nativeBuildInputs
  34         ++ (with pkgs; [
  35           # Additional dependencies required by Monado when built using Envision
  36           mesa
  37           shaderc
  38           xorg.libX11
  39           xorg.libxcb
  40           xorg.libXrandr
  41           xorg.libXrender
  42           xorg.xorgproto
  43           # Additional dependencies required for Monado WMR support
  44           bc
  45           fmt
  46           fmt.dev
  47           git-lfs
  48           gtest
  49           jq
  50           libepoxy
  51           lz4.dev
  52           tbb
  53           libxkbcommon
  54         ])
  55       )
  56     )
  57     ++ (
  58       # SteamVR driver dependencies
  59       [ pkgs.zlib ])
  60     ++ (
  61       # WiVRn dependencies
  62       pkgs.wivrn.buildInputs
  63       ++ pkgs.wivrn.nativeBuildInputs
  64       ++ (with pkgs; [
  65         glib
  66         libmd
  67         ninja
  68       ])
  69       ++ (with pkgs; [
  70         android-tools # For adb installing WiVRn APKs
  71       ])
  72     );
  73
  74   profile = ''
  75     export CMAKE_LIBRARY_PATH=/usr/lib
  76     export CMAKE_INCLUDE_PATH=/usr/include
  77     export PKG_CONFIG_PATH=/usr/lib/pkgconfig:/usr/share/pkgconfig
  78   '';
  79
  80   extraInstallCommands = ''
  81     ln -s ${envision-unwrapped}/share $out/share
  82   '';
  83
  84   runScript = "envision";
  85
  86   meta = envision-unwrapped.meta // {
  87     description = "${envision-unwrapped.meta.description} (with build environment)";
  88   };
  89 }