pkgs/by-name/eo/eos-installer/package.nix

   1 { lib, stdenv, fetchFromGitHub, writeText
   2 , glib, meson, ninja, pkg-config, python3
   3 , coreutils, gnome-desktop, gnupg, gtk3, systemdMinimal, udisks
   4 }:
   5
   6 stdenv.mkDerivation rec {
   7   pname = "eos-installer";
   8   version = "5.1.0";
   9
  10   src = fetchFromGitHub {
  11     owner = "endlessm";
  12     repo = "eos-installer";
  13     rev = "Release_${version}";
  14     sha256 = "BqvZglzFJabGXkI8hnLiw1r+CvM7kSKQPj8IKYBB6S4=";
  15     fetchSubmodules = true;
  16   };
  17
  18   strictDeps = true;
  19   nativeBuildInputs = [
  20     glib gnupg meson ninja pkg-config python3
  21   ];
  22   buildInputs = [ gnome-desktop gtk3 systemdMinimal udisks ];
  23
  24   preConfigure = ''
  25     patchShebangs tests
  26     substituteInPlace tests/test-scribe.c \
  27         --replace /bin/true ${coreutils}/bin/true \
  28         --replace /bin/false ${coreutils}/bin/false
  29   '';
  30
  31   mesonFlags = [
  32     "--libexecdir=${placeholder "out"}/bin"
  33     "--cross-file=${writeText "crossfile.ini" ''
  34       [binaries]
  35       gpg = '${gnupg}/bin/gpg'
  36     ''}"
  37   ];
  38
  39   PKG_CONFIG_SYSTEMD_SYSTEMDSYSTEMUNITDIR = "${placeholder "out"}/lib/systemd/system";
  40
  41   doCheck = true;
  42
  43   enableParallelBuilding = true;
  44
  45   meta = with lib; {
  46     homepage = "https://github.com/endlessm/eos-installer";
  47     description = "Installer UI which writes images to disk";
  48     license = licenses.gpl2Plus;
  49     maintainers = with maintainers; [ qyliss ];
  50     mainProgram = "gnome-image-installer";
  51     platforms = platforms.linux;
  52   };
  53 }