pkgs/by-name/gn/gnome-inform7/package.nix

   1 { lib, stdenv, fetchFromGitHub, meson, ninja, pkg-config, python3, perl, bison
   2 , texinfo, desktop-file-utils, wrapGAppsHook3, docbook2x, docbook-xsl-nons
   3 , inform7, gettext, libossp_uuid, gtk3, gobject-introspection, vala, gtk-doc
   4 , webkitgtk_4_0, gtksourceview3, gspell, libxml2, goocanvas2, libplist, glib
   5 , gst_all_1 }:
   6
   7 # Neither gnome-inform7 nor its dependencies ratify and chimara have tagged releases in the GTK3 branch yet.
   8
   9 let
  10   ratify = (stdenv.mkDerivation {
  11     pname = "ratify";
  12     version = "unstable-2021-02-21";
  13     src = fetchFromGitHub {
  14       owner = "ptomato";
  15       repo = "ratify";
  16       rev = "f4d2d60ec73d5588e953650b3879e69a727f30ca";
  17       sha256 = "eRh/9pYvdfbdbdJQ7pYMLq5p91I+rtyb/AqEGfakjKs=";
  18     };
  19     nativeBuildInputs = [
  20       meson
  21       ninja
  22       pkg-config
  23       docbook2x
  24       docbook-xsl-nons
  25       wrapGAppsHook3
  26       gobject-introspection
  27     ];
  28     buildInputs = [
  29       gtk3
  30       vala gtk-doc
  31     ];
  32   });
  33
  34   chimara = (stdenv.mkDerivation {
  35     pname = "chimara";
  36     version = "unstable-2021-04-06";
  37     src = fetchFromGitHub {
  38       owner = "chimara";
  39       repo = "Chimara";
  40       rev = "9934b142af508c75c0f1eed597990f39495b1af4";
  41       sha256 = "aRz1XX8XaSLTBIrMIIMS3QNMm6Msi+slrZ6+KYlyRMo=";
  42     };
  43     nativeBuildInputs = [
  44       meson
  45       ninja
  46       pkg-config
  47       perl
  48       bison
  49       texinfo
  50       python3
  51       glib
  52       wrapGAppsHook3
  53       gobject-introspection
  54     ];
  55     buildInputs = [
  56       gtk3
  57       vala
  58       gtk-doc
  59       gst_all_1.gstreamer
  60       gst_all_1.gst-plugins-base
  61       gst_all_1.gst-plugins-good
  62       gst_all_1.gst-plugins-bad
  63       glib
  64     ];
  65     preConfigure = ''
  66       patchShebangs build-aux/meson_post_install.py
  67     '';
  68   });
  69
  70 in stdenv.mkDerivation {
  71   pname = "gnome-inform7";
  72   version = "unstable-2021-04-06";
  73   src = fetchFromGitHub {
  74     owner = "ptomato";
  75     repo = "gnome-inform7";
  76     # build from revision in the GTK3 branch as mainline requires webkit-1.0
  77     rev = "c37e045c159692aae2e4e79b917e5f96cfefa66a";
  78     sha256 = "Q4xoITs3AYXhvpWaABRAvJaUWTtUl8lYQ1k9zX7FrNw=";
  79   };
  80   nativeBuildInputs = [
  81     meson
  82     ninja
  83     pkg-config
  84     inform7
  85     python3
  86     desktop-file-utils
  87     wrapGAppsHook3
  88   ];
  89   buildInputs = [
  90     gettext
  91     libossp_uuid
  92     gtk3
  93     gtksourceview3
  94     gspell
  95     webkitgtk_4_0
  96     libxml2
  97     goocanvas2
  98     libplist
  99     ratify
 100     chimara
 101   ];
 102   preConfigure = ''
 103     cp ${inform7}/libexec/ni ./src/ni
 104     patchShebangs build-aux/* src/generate-resource-xml.{py,sh}
 105   '';
 106
 107   meta = with lib; {
 108     description = "Inform 7 for the Gnome platform";
 109     longDescription = ''
 110       This version of Inform 7 for the Gnome platform was created by Philip Chimento, based on a design by Graham Nelson and Andrew Hunter.
 111     '';
 112     homepage = "https://github.com/ptomato/gnome-inform7";
 113     license = licenses.gpl3Only;
 114     maintainers = [ maintainers.fitzgibbon ];
 115     platforms = platforms.linux;
 116     mainProgram = "gnome-inform7";
 117   };
 118 }