pkgs/by-name/go/go-ios/package.nix

   1 { lib
   2 , buildGoModule
   3 , fetchFromGitHub
   4 , nix-update-script
   5 , pkg-config
   6 , libusb1
   7 }:
   8
   9 buildGoModule rec {
  10   pname = "go-ios";
  11   version = "1.0.150";
  12
  13   src = fetchFromGitHub {
  14     owner = "danielpaulus";
  15     repo = "go-ios";
  16     rev = "v${version}";
  17     sha256 = "sha256-xa2/qshZ4k+Df5l817BXlotR6L/CX6Lw2+tWDYnr96I=";
  18   };
  19
  20   proxyVendor = true;
  21   vendorHash = "sha256-/aVaTC9lfoXQvhDVQm31HmXBnDYYOv6RH69Nm3I/K7s=";
  22
  23   excludedPackages = [
  24     "restapi"
  25   ];
  26
  27   nativeBuildInputs = [
  28     pkg-config
  29   ];
  30
  31   buildInputs = [
  32     libusb1
  33   ];
  34
  35   postInstall = ''
  36     # aligns the binary with what is expected from go-ios
  37     mv $out/bin/go-ios $out/bin/ios
  38   '';
  39
  40   # skips all the integration tests (requires iOS device) (`-tags=fast`)
  41   # as well as tests that requires networking
  42   checkFlags = let
  43     skippedTests = [
  44       "TestWorksWithoutProxy"
  45       "TestUsesProxy"
  46     ];
  47   in [ "-tags=fast" ]
  48   ++ [ "-skip=^${builtins.concatStringsSep "$|^" skippedTests}$" ];
  49
  50   passthru.updateScript = nix-update-script { };
  51
  52   meta = with lib; {
  53     description = "Operating system independent implementation of iOS device features";
  54     homepage = "https://github.com/danielpaulus/go-ios";
  55     license = licenses.mit;
  56     maintainers = with maintainers; [ eyjhb ];
  57     mainProgram = "ios";
  58   };
  59 }