pkgs/by-name/gw/gwyddion/package.nix

   1 { lib, stdenv, fetchurl, gtk2, pkg-config, fftw, file,
   2   gnome2,
   3   openexrSupport ? true, openexr,
   4   libzipSupport ? true, libzip,
   5   libxml2Support ? true, libxml2,
   6   libwebpSupport ? true, libwebp,
   7   # libXmu is not used if libunique is.
   8   libXmuSupport ? false, xorg,
   9   libxsltSupport ? true, libxslt,
  10   fitsSupport ? true, cfitsio,
  11   zlibSupport ? true, zlib,
  12   libuniqueSupport ? true, libunique,
  13   libpngSupport ? true, libpng,
  14   openglSupport ? !stdenv.hostPlatform.isDarwin, libGL
  15 }:
  16
  17 stdenv.mkDerivation rec {
  18   pname = "gwyddion";
  19    version = "2.66";
  20   src = fetchurl {
  21     url = "mirror://sourceforge/gwyddion/gwyddion-${version}.tar.xz";
  22     sha256 = "sha256-N3vtzSsNjRM6MpaG2p9fkYB/8dR5N/mZEZXx6GN5LVI=";
  23   };
  24
  25   nativeBuildInputs = [ pkg-config file ];
  26
  27   buildInputs = [ gtk2 fftw ] ++
  28     lib.optionals openglSupport [ gnome2.gtkglext libGL ] ++
  29     lib.optional openexrSupport openexr ++
  30     lib.optional libXmuSupport xorg.libXmu ++
  31     lib.optional fitsSupport cfitsio ++
  32     lib.optional libpngSupport libpng ++
  33     lib.optional libxsltSupport libxslt ++
  34     lib.optional libxml2Support libxml2 ++
  35     lib.optional libwebpSupport libwebp ++
  36     lib.optional zlibSupport zlib ++
  37     lib.optional libuniqueSupport libunique ++
  38     lib.optional libzipSupport libzip;
  39
  40   # This patch corrects problems with python support, but should apply cleanly
  41   # regardless of whether python support is enabled, and have no effects if
  42   # it is disabled.
  43   patches = [ ./codegen.patch ];
  44   meta = {
  45     homepage = "http://gwyddion.net/";
  46
  47     description = "Scanning probe microscopy data visualization and analysis";
  48
  49     longDescription = ''
  50       A modular program for SPM (scanning probe microscopy) data
  51       visualization and analysis. Primarily it is intended for the
  52       analysis of height fields obtained by scanning probe microscopy
  53       techniques (AFM, MFM, STM, SNOM/NSOM) and it supports a lot of
  54       SPM data formats. However, it can be used for general height
  55       field and (greyscale) image processing, for instance for the
  56       analysis of profilometry data or thickness maps from imaging
  57       spectrophotometry.
  58     '';
  59     license = lib.licenses.gpl2;
  60     platforms = with lib.platforms; linux ++ darwin;
  61     maintainers = [ ];
  62     # never built on aarch64-darwin since first introduction in nixpkgs
  63     broken = stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64;
  64   };
  65 }