pkgs/by-name/m2/m2-mesoplanet/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , m2libc
   5 , mescc-tools
   6 }:
   7
   8 stdenv.mkDerivation (finalAttrs: {
   9   pname = "m2-mesoplanet";
  10   version = "1.11.0";
  11
  12   src = fetchFromGitHub {
  13     owner = "oriansj";
  14     repo = "M2-Mesoplanet";
  15     rev = "Release_${finalAttrs.version}";
  16     hash = "sha256-hE7xvX84q3tk0XakveYDJhrhfBnpoItQs456NCzFfws=";
  17   };
  18
  19   # Don't use vendored M2libc
  20   postPatch = ''
  21     rmdir M2libc
  22     ln -s ${m2libc}/include/M2libc M2libc
  23   '';
  24
  25   # Upstream overrides the optimisation to be -O0, which is incompatible with fortify. Let's disable it.
  26   hardeningDisable = [ "fortify" ];
  27
  28   doCheck = true;
  29   checkTarget = "test";
  30   nativeCheckInputs = [ mescc-tools ];
  31
  32   installPhase = ''
  33     runHook preInstall
  34
  35     install -D bin/M2-Mesoplanet $out/bin/M2-Mesoplanet
  36
  37     runHook postInstall
  38   '';
  39
  40   meta = with lib; {
  41     description = "Macro Expander Saving Our m2-PLANET";
  42     homepage = "https://github.com/oriansj/M2-Mesoplanet";
  43     license = licenses.gpl3Only;
  44     maintainers = teams.minimal-bootstrap.members;
  45     inherit (m2libc.meta) platforms;
  46     mainProgram = "M2-Mesoplanet";
  47   };
  48 })