pkgs/by-name/ma/mako/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   meson,
   6   ninja,
   7   pkg-config,
   8   scdoc,
   9   systemd,
  10   pango,
  11   cairo,
  12   gdk-pixbuf,
  13   jq,
  14   bash,
  15   wayland,
  16   wayland-scanner,
  17   wayland-protocols,
  18   wrapGAppsHook3,
  19 }:
  20
  21 stdenv.mkDerivation (finalAttrs: {
  22   pname = "mako";
  23   version = "1.9.0";
  24
  25   src = fetchFromGitHub {
  26     owner = "emersion";
  27     repo = "mako";
  28     rev = "refs/tags/v${finalAttrs.version}";
  29     hash = "sha256-QtYtondP7E5QXLRnmcaOQlAm9fKXctfjxeUFqK6FnnE=";
  30   };
  31
  32   strictDeps = true;
  33   depsBuildBuild = [ pkg-config ];
  34   nativeBuildInputs = [
  35     meson
  36     ninja
  37     pkg-config
  38     scdoc
  39     wayland-protocols
  40     wrapGAppsHook3
  41     wayland-scanner
  42   ];
  43   buildInputs = [
  44     systemd
  45     pango
  46     cairo
  47     gdk-pixbuf
  48     wayland
  49   ];
  50
  51   mesonFlags = [
  52     "-Dzsh-completions=true"
  53     "-Dsd-bus-provider=libsystemd"
  54   ];
  55
  56   preFixup = ''
  57     gappsWrapperArgs+=(
  58       --prefix PATH : "${
  59         lib.makeBinPath [
  60           systemd # for busctl
  61           jq
  62           bash
  63         ]
  64       }"
  65     )
  66   '';
  67
  68   postInstall = ''
  69     mkdir -p $out/lib/systemd/user
  70     substitute $src/contrib/systemd/mako.service $out/lib/systemd/user/mako.service \
  71       --replace-fail '/usr/bin' "$out/bin"
  72     chmod 0644 $out/lib/systemd/user/mako.service
  73   '';
  74
  75   meta = {
  76     description = "Lightweight Wayland notification daemon";
  77     homepage = "https://wayland.emersion.fr/mako/";
  78     license = lib.licenses.mit;
  79     maintainers = with lib.maintainers; [
  80       dywedir
  81       synthetica
  82     ];
  83     platforms = lib.platforms.linux;
  84     mainProgram = "mako";
  85   };
  86 })