pkgs/by-name/of/offlineimap/package.nix

   1 { lib
   2 , fetchFromGitHub
   3 , python3
   4 , asciidoc
   5 , cacert
   6 , docbook_xsl
   7 , installShellFiles
   8 , libxml2
   9 , libxslt
  10 , testers
  11 , offlineimap
  12 , fetchpatch
  13 }:
  14
  15 python3.pkgs.buildPythonApplication rec {
  16   pname = "offlineimap";
  17   version = "8.0.0";
  18   pyproject = true;
  19
  20   src = fetchFromGitHub {
  21     owner = "OfflineIMAP";
  22     repo = "offlineimap3";
  23     rev = "v${version}";
  24     hash = "sha256-XLxKqO5OCXsFu8S3lMp2Ke5hp6uer9npZ3ujmL6Kb3g=";
  25   };
  26
  27   patches = [
  28     (fetchpatch {
  29       name = "sqlite-version-aware-threadsafety-check.patch";
  30       url = "https://github.com/OfflineIMAP/offlineimap3/pull/139/commits/7cd32cf834b34a3d4675b29bebcd32dc1e5ef128.patch";
  31       hash = "sha256-xNq4jFHMf9XZaa9BFF1lOzZrEGa5BEU8Dr+gMOBkJE4=";
  32     })
  33     (fetchpatch {
  34       # https://github.com/OfflineIMAP/offlineimap3/pull/120
  35       name = "python312-comaptibility.patch";
  36       url = "https://github.com/OfflineIMAP/offlineimap3/commit/a1951559299b297492b8454850fcfe6eb9822a38.patch";
  37       hash = "sha256-CBGMHi+ZzOBJt3TxBf6elrTRMIQ+8wr3JgptL2etkoA=";
  38      })
  39     (fetchpatch {
  40       # https://github.com/OfflineIMAP/offlineimap3/pull/161
  41       name = "python312-compatibility.patch";
  42       url = "https://github.com/OfflineIMAP/offlineimap3/commit/3dd8ebc931e3f3716a90072bd34e50ac1df629fa.patch";
  43       hash = "sha256-2IJ0yzESt+zk+r+Z+9js3oKhFF0+xok0xK8Jd3G/gYY=";
  44      })
  45   ];
  46
  47   postPatch = ''
  48     # Skip xmllint to stop failures due to no network access
  49     sed -i docs/Makefile -e "s|a2x -v -d |a2x -L -v -d |"
  50
  51     # Provide CA certificates (Used when "sslcacertfile = OS-DEFAULT" is configured")
  52     sed -i offlineimap/utils/distro_utils.py -e '/def get_os_sslcertfile():/a\ \ \ \ return "${cacert}/etc/ssl/certs/ca-bundle.crt"'
  53   '';
  54
  55   build-system = [ python3.pkgs.setuptools ];
  56
  57   nativeBuildInputs = [
  58     asciidoc
  59     docbook_xsl
  60     installShellFiles
  61     libxml2
  62     libxslt
  63   ];
  64
  65   dependencies = with python3.pkgs; [
  66     certifi
  67     distro
  68     imaplib2
  69     pysocks
  70     rfc6555
  71     urllib3
  72   ];
  73
  74   postInstall = ''
  75     make -C docs man
  76     installManPage docs/offlineimap.1
  77     installManPage docs/offlineimapui.7
  78   '';
  79
  80   # Test requires credentials
  81   doCheck = false;
  82
  83   pythonImportsCheck = [
  84     "offlineimap"
  85   ];
  86
  87   passthru.tests.version = testers.testVersion { package = offlineimap; };
  88
  89   meta = with lib; {
  90     description = "Synchronize emails between two repositories, so that you can read the same mailbox from multiple computers";
  91     homepage = "http://offlineimap.org";
  92     license = licenses.gpl2Plus;
  93     maintainers = [ ];
  94     mainProgram = "offlineimap";
  95   };
  96 }